Adding initial deployment assets

contains mongodb and azure openai resources.

Author: codingbandit

Labs/deploy/azuredeploy.bicep

@@ -0,0 +1,144 @@
+@description('Location where all resources will be deployed. This value defaults to the **East US** region.')
+@allowed([  
+  'eastus'  
+  'francecentral'
+  'southcentralus'
+  'uksouth'
+  'westeurope'
+])
+param location string = 'eastus'
+
+@description('''
+Unique name for the deployed services below. Max length 15 characters, alphanumeric only:
+- Azure Cosmos DB for MongoDB vCore
+- Azure OpenAI Service
+
+The name defaults to a unique string generated from the resource group identifier.
+''')
+@maxLength(15)
+param name string = uniqueString(resourceGroup().id)
+
+@description('Specifies the SKU for the Azure OpenAI resource. Defaults to **S0**')
+@allowed([
+  'S0'
+])
+param openAiSku string = 'S0'
+
+@description('MongoDB vCore user Name. No dashes.')
+param mongoDbUserName string
+
+@description('MongoDB vCore password. 8-256 characters, 3 of the following: lower case, upper case, numeric, symbol.')
+@minLength(8)
+@maxLength(256)
+@secure()
+param mongoDbPassword string
+
+var openAiSettings = {
+  name: '${name}-openai'
+  sku: openAiSku
+  maxConversationTokens: '100'
+  maxCompletionTokens: '500'
+  completionsModel: {
+    name: 'gpt-35-turbo'
+    version: '0301'
+    deployment: {
+      name: 'completions'
+    }
+  }
+  embeddingsModel: {
+    name: 'text-embedding-ada-002'
+    version: '2'
+    deployment: {
+      name: 'embeddings'
+    }
+  }
+}
+
+var mongovCoreSettings = {
+  mongoClusterName: '${name}-mongo'
+  mongoClusterLogin: mongoDbUserName
+  mongoClusterPassword: mongoDbPassword
+}
+
+resource mongoCluster 'Microsoft.DocumentDB/mongoClusters@2023-03-01-preview' = {
+  name: mongovCoreSettings.mongoClusterName
+  location: location
+  properties: {
+    administratorLogin: mongovCoreSettings.mongoClusterLogin
+    administratorLoginPassword: mongovCoreSettings.mongoClusterPassword
+    serverVersion: '5.0'
+    nodeGroupSpecs: [
+      {
+        kind: 'Shard'
+        sku: 'M30'
+        diskSizeGB: 128
+        enableHa: false
+        nodeCount: 1
+      }
+    ]
+  }
+}
+
+resource mongoFirewallRulesAllowAzure 'Microsoft.DocumentDB/mongoClusters/firewallRules@2023-03-01-preview' = {
+  parent: mongoCluster
+  name: 'allowAzure'
+  properties: {
+    startIpAddress: '0.0.0.0'
+    endIpAddress: '0.0.0.0'
+  }
+}
+
+resource mongoFirewallRulesAllowAll 'Microsoft.DocumentDB/mongoClusters/firewallRules@2023-03-01-preview' = {
+  parent: mongoCluster
+  name: 'allowAll'
+  properties: {
+    startIpAddress: '0.0.0.0'
+    endIpAddress: '255.255.255.255'
+  }
+}
+
+resource openAiAccount 'Microsoft.CognitiveServices/accounts@2022-12-01' = {
+  name: openAiSettings.name
+  location: location
+  sku: {
+    name: openAiSettings.sku
+  }
+  kind: 'OpenAI'
+  properties: {
+    customSubDomainName: openAiSettings.name
+    publicNetworkAccess: 'Enabled'
+  }
+}
+
+resource openAiEmbeddingsModelDeployment 'Microsoft.CognitiveServices/accounts/deployments@2022-12-01' = {
+  parent: openAiAccount
+  name: openAiSettings.embeddingsModel.deployment.name
+  properties: {
+    model: {
+      format: 'OpenAI'
+      name: openAiSettings.embeddingsModel.name
+      version: openAiSettings.embeddingsModel.version
+    }
+    scaleSettings: {
+      scaleType: 'Standard'
+    }
+  }
+}
+
+resource openAiCompletionsModelDeployment 'Microsoft.CognitiveServices/accounts/deployments@2022-12-01' = {
+  parent: openAiAccount
+  name: openAiSettings.completionsModel.deployment.name
+  properties: {
+    model: {
+      format: 'OpenAI'
+      name: openAiSettings.completionsModel.name
+      version: openAiSettings.completionsModel.version
+    }
+    scaleSettings: {
+      scaleType: 'Standard'
+    }
+  }
+  dependsOn: [
+    openAiEmbeddingsModelDeployment
+  ]
+}

Labs/deploy/azuredeploy.parameters.json

@@ -0,0 +1,22 @@
+{
+    "$schema": "https://schema.management.azure.com/schemas/2019-04-01/deploymentParameters.json#",
+    "contentVersion": "1.0.0.0",
+    "parameters": {
+        "location": { 
+            "value": "eastus"
+        },
+        "name": {
+            "value": "mongodb-aoai"
+        },
+        "openAiSku": {
+            "value": "S0"
+        },        
+        "mongoDbUserName": {
+            "value": "S0"
+        },
+        
+        "mongoDbPassword": {
+            "value": "meye$ecr3t"
+        }        
+    }
+}

Labs/deploy/deploy.md

@@ -0,0 +1,38 @@
+# Solution deployment
+
+## Prerequisites
+
+- Owner on Azure subscription
+- Account approved for Azure OpenAI service
+- Azure CLI installed
+- Azure PowerShell installed
+
+## Login to Azure
+
+Open a terminal window and log in to Azure using the following command:
+
+```Powershell
+Connect-AzAccount
+```
+
+### Set the desired subscription (Optional)
+
+If you have more than one subscription associated with your account, set the desired subscription using the following command:
+
+```Powershell
+Set-AzContext -SubscriptionId <subscription-id>
+```
+
+## Create resource group
+
+```Powershell
+New-AzResourceGroup -Name mongodb-aoai-rg -Location 'eastus'
+```
+
+## Deploy using bicep template
+
+Deploy the solution resources using the following command (this will take a few minutes to run):
+
+```Powershell
+New-AzResourceGroupDeployment -ResourceGroupName mongodb-aoai-rg -TemplateFile .\azuredeploy.bicep -TemplateParameterFile .\azuredeploy.parameters.json -c
+```