Trying to attach to a cylinder, but instead to a cuboid child instead.

[NakedMoleRatScientist]

include <bols2/std.scad>


$fa = 1;
$fs = 0.1;

module hole()
{
    diff()
        cylinder(2,5,5,center = true)
            attach(LEFT,RIGHT,inside=true)
                tag("") cuboid([5,10,2])
            attach(CENTER,CENTER,inside=true)
                tag("remove") cylinder(2.1,2.5,2.5,center=true);

}

hole();

For the most part, I figured out how to do what I want it to do, but almost there. For some reason, the hole I am trying to attach to the cylinder seems to be attaching to the cuboid instead of the cylinder.

Manipulating it a little bit will make it look right.

include <bols2/std.scad>


$fa = 1;
$fs = 0.1;

module hole()
{
    diff()
        cylinder(2,5,5,center = true)
            attach(LEFT,RIGHT,inside=true)
                tag("") cuboid([5,10,2])
            attach(CENTER,CENTER,inside=true)
                tag("remove") right(2.5) cylinder(2.1,2.5,2.5,center=true);

}

hole();

I just did right(2.5) to move the hole a little bit, but I am unsatisfied since it is a workaround for my inability to do it the "proper" and clean way.

[jordanbrown0]

You've got the second attach as a child of the cuboid, not of the cylinder.

Your indentation is right, but the punctuation is wrong so the program structure is not what you think it is.
Here is how the program should be indented to match its actual structure:

    diff()
        cylinder(2,5,5,center = true)
            attach(LEFT,RIGHT,inside=true)
                tag("") cuboid([5,10,2])
                    attach(CENTER,CENTER,inside=true)
                        tag("remove") cylinder(2.1,2.5,2.5,center=true);

What you need is:

    diff()
        cylinder(2,5,5,center = true) {          // added open brace
            attach(LEFT,RIGHT,inside=true)
                tag("") cuboid([5,10,2]);        // added semicolon
            attach(CENTER,CENTER,inside=true)
                tag("remove") cylinder(2.1,2.5,2.5,center=true);
        }                                        // added close brace

[NakedMoleRatScientist]

Thank you! This works. I now know what to look for next time.

[jordanbrown0]

Happy to help. We need a misleading-indentation linter...