Add no_offset_view (#66)

Author: tpapp

src/OffsetArrays.jl

@@ -200,4 +200,39 @@ printindices(io::IO, ind1) = print(io, _unslice(ind1))
 _unslice(x) = x
 _unslice(x::IdentityUnitRange) = x.indices
 
+"""
+    no_offset_view(A)
+
+Return an `AbstractArray` that shares structure and has the same type and size as the
+argument, but has 1-based indexing. May just return the argument when applicable. Not
+exported.
+
+The default implementation uses `OffsetArrays`, but other types should use something more
+specific to remove a level of indirection when applicable.
+
+```jldoctest
+julia> O = OffsetArray(A, 0:1, -1:1)
+OffsetArray(::Array{Int64,2}, 0:1, -1:1) with eltype Int64 with indices 0:1×-1:1:
+ 1  3  5
+ 2  4  6
+
+julia> OffsetArrays.no_offset_view(O)[1,1] = -9
+-9
+
+julia> A
+2×3 Array{Int64,2}:
+ -9  3  5
+  2  4  6
+```
+"""
+function no_offset_view(A::AbstractArray)
+    if Base.has_offset_axes(A)
+        OffsetArray(A, map(r->1-first(r), axes(A)))
+    else
+        A
+    end
+end
+
+no_offset_view(A::OffsetArray) = no_offset_view(parent(A))
+
 end # module

test/REQUIRE

@@ -0,0 +1 @@
+CatIndices

test/runtests.jl

@@ -1,7 +1,8 @@
 using OffsetArrays
 using Test
 using DelimitedFiles
-using OffsetArrays: IdentityUnitRange
+using OffsetArrays: IdentityUnitRange, no_offset_view
+using CatIndices: BidirectionalVector
 
 @test isempty(detect_ambiguities(OffsetArrays, Base, Core))
 
@@ -402,6 +403,44 @@ end
     @test typeof(OffsetVector{Float64}(undef, -2:2)) == typeof(OffsetArray{Float64}(undef, -2:2))
 end
 
+####
+#### type defined for testing no_offset_view
+####
+
+struct NegativeArray{T,N,S <: AbstractArray{T,N}} <: AbstractArray{T,N}
+    parent::S
+end
+
+Base.axes(A::NegativeArray) = map(n -> (-n):(-1), size(A.parent))
+
+Base.size(A::NegativeArray) = size(A.parent)
+
+function Base.getindex(A::NegativeArray{T,N}, I::Vararg{Int,N}) where {T,N}
+    getindex(A.parent, (I .+ size(A.parent) .+ 1)...)
+end
+
+@testset "no offset view" begin
+    # OffsetArray fallback
+    A = randn(3, 3)
+    O1 = OffsetArray(A, -1:1, 0:2)
+    O2 = OffsetArray(O1, -2:0, -3:(-1))
+    @test no_offset_view(O2) ≡ A
+
+    # generic fallback
+    A = collect(reshape(1:12, 3, 4))
+    N = NegativeArray(A)
+    @test N[-3, -4] == 1
+    V = no_offset_view(N)
+    @test collect(V) == A
+
+    # bidirectional
+    B = BidirectionalVector([1, 2, 3])
+    pushfirst!(B, 0)
+    OB = OffsetArrays.no_offset_view(B)
+    @test axes(OB, 1) == 1:4
+    @test collect(OB) == 0:3
+end
+  
 @testset "no nesting" begin
     A = randn(2, 3)
     x = A[2, 2]