fixes and tests for #51 (#52)

fixes #46 #50

Author: tanmaykm

src/client.jl

@@ -602,48 +602,75 @@ is_request_interrupted(ex::InvocationException) = ex.reason == "request was inte
 
 
 """
-    deserialize_file(api_call::Function;
-        folder_path::String=pwd(),
+    storefile(api_call::Function;
+        folder::AbstractString = pwd(),
         rename_file::String="",
-        overwrite::Bool=true
         )::Tuple{Any,ApiResponse,String}
 
-    Saves response body into a file in a temporary folder,
-    using the filename from the `Content-Disposition` header if provided.
-    - `api_call`: API function that return `(result, http_response)` Tuple.
-    - `folder_path`: file save location, default value is `pwd()``.
-    - `rename_file`: rename the file, default value is `""`.
-    - return: (result, http_response, file_path).
+    Helper method that stores the result of an API call that returns file
+    contents (as binary or text string) into a file.
+
+    Convenient to use it in a do block. Returns the path where file is stored additionally.
+
+    E.g.:
+    ```
+    _result, _http_response, file = OpenAPI.Clients.storefile() do
+        # Invoke the OpenaPI method that returns file contents.
+        # This is the method that returns a tuple of (result, http_response).
+        # The result is the file contents as binary or text string.
+        fetch_file(api, "reports", "category1")
+    end
+    ```
+
+    Parameters:
+
+    - `api_call`: The OpenAPI function call that returns file contents (as binary or text string). See example in method description.
+    - `folder`: Location to store file, defaults to `pwd()`.
+    - `filename`: Use this filename, overrides any filename that may be there in the `Content-Disposition` header.
+
+    Returns: (result, http_response, file_path)
 """
-function deserialize_file(api_call::Function;
-    folder_path::String=pwd(),
-    rename_file::String="",
+function storefile(api_call::Function;
+    folder::AbstractString = pwd(),
+    filename::Union{String,Nothing} = nothing,
     )::Tuple{Any,ApiResponse,String}
 
     result, http_response = api_call()
 
-    content_disposition_str = OpenAPI.Clients.header(http_response.raw,"content-disposition","")
-    content_type_str = extract_filename(OpenAPI.Clients.header(http_response.raw,"content-type",""))
-    
-    file_name = if !isempty(rename_file)
-        rename_file
-    elseif !isempty(content_disposition_str)
-        content_disposition_str
-    else 
-        "response"*extension_from_mime(MIME(content_type_str))
+    if isnothing(filename)
+        filename = extract_filename(http_response)
     end
 
-    file_path = joinpath(mkpath(folder_path),file_name)
-    open(file_path,"w") do file
-        write(file,result)
+    mkpath(folder)
+    filepath = joinpath(folder, filename)
+
+    open(filepath, "w") do io
+        write(io, result)
     end
-    return result, http_response, file_path
+
+    return result, http_response, filepath
 end
 
-# extract_filename from content-disposition
-function extract_filename(str::String)::String
-    m = match(r"filename=\"(.*?)\"",str)
-    return isnothing(m) ? "" : m.captures[1]
+const content_disposition_re = r"filename\*?=['\"]?(?:UTF-\d['\"]*)?([^;\r\n\"']*)['\"]?;?"
+
+"""
+    extract_filename(resp::Downloads.Response)::String
+
+Extracts the filename from the `Content-Disposition` header of the HTTP response.
+If not found, then creates a filename from the `Content-Type` header.
+"""
+extract_filename(resp::ApiResponse) = extract_filename(resp.raw)
+function extract_filename(resp::Downloads.Response)::String
+    # attempt to extract filename from content-disposition header
+    content_disposition_str = header(resp, "content-disposition", "")
+    m = match(content_disposition_re, content_disposition_str)
+    if !isnothing(m) && !isempty(m.captures) && !isnothing(m.captures[1])
+        return m.captures[1]
+    end
+
+    # attempt to create a filename from content-type header
+    content_type_str = header(resp, "content-type", "")
+    return string("response", extension_from_mime(MIME(content_type_str)))
 end
 
 end # module Clients

test/client/runtests.jl

@@ -17,6 +17,7 @@ function runtests(; skip_petstore=false, test_file_upload=false)
             test_date()
             test_misc()
             test_has_property()
+            test_storefile()
         end
         @testset "Validations" begin
             test_validations()

test/client/utilstests.jl

@@ -4,6 +4,7 @@ using Test
 using Dates
 using TimeZones
 using Base64
+using Downloads
 
 function test_date()
     dt_now = now()
@@ -242,4 +243,55 @@ function test_misc()
     @test OpenAPI.from_json(Any, json) === json
     @test OpenAPI.from_json(String, json) == "{}"
     @test isa(OpenAPI.from_json(Dict{Any,Any}, json), Dict{Any,Any})
+end
+
+const content_disposition_tests = [
+    (content_disposition="attachment; filename=content.txt", content_type="", filename="content.txt"),
+    (content_disposition="attachment; filename*=UTF-8''filename.txt", content_type="", filename="filename.txt"),
+    (content_disposition="attachment; filename=\"Image File\"; filename*=utf-8''UTF8ImageFile", content_type="", filename="Image File"),
+    (content_disposition="attachment; filename=\"चित्त.jpg\"", content_type="", filename="चित्त.jpg"),
+    (content_disposition="", content_type="", filename="response"),
+    (content_disposition="", content_type="image/jpg", filename="response"),
+]
+
+function test_storefile()
+    for test_data in content_disposition_tests
+        headers = [
+            "Content-Disposition" => test_data.content_disposition,
+            "Content-Type" => test_data.content_type,
+        ]
+        resp = Downloads.Response("GET", "http://test/", 200, "", headers)
+
+        @test OpenAPI.Clients.extract_filename(resp) == test_data.filename
+    end
+
+    mktempdir() do tmpdir
+        test_data = content_disposition_tests[1]
+        headers = [
+            "Content-Disposition" => test_data.content_disposition,
+            "Content-Type" => test_data.content_type,
+        ]
+        resp = OpenAPI.Clients.ApiResponse(Downloads.Response("GET", "http://test/", 200, "", headers))
+        file_contents = "test file data"
+
+        # test extraction of filename from headers
+        result, http_response, filepath = OpenAPI.Clients.storefile(; folder=tmpdir) do
+            return file_contents, resp
+        end
+
+        @test result == file_contents
+        @test http_response == resp
+        @test filepath == joinpath(tmpdir, test_data.filename)
+        @test read(filepath, String) == file_contents
+
+        # test overriding filename
+        result, http_response, filepath = OpenAPI.Clients.storefile(; folder=tmpdir, filename="overridename.txt") do
+            return file_contents, resp
+        end
+
+        @test result == file_contents
+        @test http_response == resp
+        @test filepath == joinpath(tmpdir, "overridename.txt")
+        @test read(filepath, String) == file_contents
+    end
 end