Create default (::Node, ...)() and adjoint methods

Author: MilesCranmer

src/DynamicExpressions.jl

@@ -6,6 +6,7 @@ include("Equation.jl")
 include("EquationUtils.jl")
 include("EvaluateEquation.jl")
 include("EvaluateEquationDerivative.jl")
+include("EvaluationHelpers.jl")
 include("InterfaceSymbolicUtils.jl")
 include("SimplifyEquation.jl")
 include("OperatorEnumConstruction.jl")
@@ -31,6 +32,7 @@ using Reexport
     eval_diff_tree_array, eval_grad_tree_array
 @reexport import .InterfaceSymbolicUtilsModule: node_to_symbolic, symbolic_to_node
 @reexport import .SimplifyEquationModule: combine_operators, simplify_tree
+@reexport import .EvaluationHelpersModule
 
 import TOML: parsefile
 

src/EvaluationHelpers.jl

@@ -0,0 +1,38 @@
+module EvaluationHelpersModule
+
+import Base: adjoint
+import ..OperatorEnumModule: AbstractOperatorEnum, OperatorEnum, GenericOperatorEnum
+import ..EquationModule: Node
+import ..EvaluateEquationModule: eval_tree_array
+import ..EvaluateEquationDerivativeModule: eval_grad_tree_array
+
+# Evaluation:
+function (tree::Node)(X, operators::OperatorEnum; kws...)
+    out, did_finish = eval_tree_array(tree, X, operators; kws...)
+    !did_finish && (out .= convert(eltype(out), NaN))
+    return out
+end
+function (tree::Node)(X, operators::GenericOperatorEnum; kws...)
+    out, did_finish = eval_tree_array(tree, X, operators; kws...)
+    !did_finish && return nothing
+    return out
+end
+function (tree::Node)(X; kws...)
+    @error "The `tree(X; kws...)` syntax is deprecated. Use `tree(X, operators; kws...)` instead."
+end
+
+# Gradients:
+function _grad_evaluator(tree::Node, X, operators::OperatorEnum; kws...)
+    _, grad, did_complete = eval_grad_tree_array(tree, X, operators; variable=true, kws...)
+    !did_complete && (grad .= convert(eltype(grad), NaN))
+    return grad
+end
+function _grad_evaluator(tree::Node, X, operators::GenericOperatorEnum; kws...)
+    @error "Gradients are not implemented for `GenericOperatorEnum`."
+end
+function _grad_evaluator(tree::Node, X; kws...)
+    @error "The `tree'(X; kws...)` syntax is deprecated. Use `tree'(X, operators; kws...)` instead."
+end
+Base.adjoint(tree::Node) = ((args...; kws...) -> _grad_evaluator(tree, args...; kws...))
+
+end