[Question] How to integrate ZLS?

[highjeans]

I have ZLS installed for LSP support, however I am unsure as to how to provide a "check" step that only tries to build the firmware but doesn't install it. How should I do this?

[tact1m4n3]

You can depend on firmware.artifact.step. Here is an example:

const std = @import("std");
const microzig = @import("microzig");

const MicroBuild = microzig.MicroBuild(.{
    .esp = true,
});

pub fn build(b: *std.Build) void {
    const optimize = b.standardOptimizeOption(.{});

    const mb = MicroBuild.init(b, b.dependency("microzig", .{})) orelse return;

    const firmware = make_firmware(mb, optimize);
    mb.install_firmware(firmware, .{});
    mb.install_firmware(firmware, .{ .format = .elf });

    const firmware_check = make_firmware(mb, optimize);
    const step = b.step("check", "Check step");
    step.dependOn(&firmware_check.artifact.step);
}

pub fn make_firmware(mb: *MicroBuild, optimize: std.builtin.OptimizeMode) *MicroBuild.Firmware {
    const b = mb.builder;

    const firmware = mb.add_firmware(.{
        .name = "tcp_server",
        .root_source_file = mb.builder.path("src/main.zig"),
        .target = mb.ports.esp.chips.esp32_c3,
        .optimize = optimize,
    });

    const target = b.resolveTargetQuery(firmware.target.zig_target);

    const foundation_dep = b.dependency("foundation_libc", .{
        .target = target,
        .optimize = optimize,
        .single_threaded = true,
    });

    const lwip_dep = b.dependency("lwip", .{
        .target = target,
        .optimize = optimize,
        .include_dir = b.path("src/lwip/include"),
    });

    const libc_lib = foundation_dep.artifact("foundation");
    const lwip_lib = lwip_dep.artifact("lwip");

    lwip_lib.root_module.linkLibrary(libc_lib);
    firmware.app_mod.linkLibrary(lwip_lib);

    return firmware;
}