fixup! build: update to bazel version 8.4.2

Author: alan-agius4

MODULE.bazel

@@ -9,17 +9,8 @@ bazel_dep(name = "yq.bzl", version = "0.3.2")
 bazel_dep(name = "rules_nodejs", version = "6.6.2")
 bazel_dep(name = "aspect_rules_js", version = "2.8.3")
 bazel_dep(name = "aspect_rules_ts", version = "3.7.1")
-bazel_dep(name = "rules_pkg", version = "0.8.1")
-
-# Alow for usage of rules_pkg@0.8.1 even though other deps want a later verison.
-multiple_version_override(
-    module_name = "rules_pkg",
-    versions = [
-        "0.8.1",
-        "1.1.0",
-    ],
-)
-
+bazel_dep(name = "rules_pkg", version = "1.1.0")
+bazel_dep(name = "rules_cc", version = "0.0.9")
 bazel_dep(name = "aspect_bazel_lib", version = "2.22.0")
 bazel_dep(name = "bazel_skylib", version = "1.8.2")
 bazel_dep(name = "aspect_rules_esbuild", version = "0.24.0")
@@ -173,4 +164,5 @@ register_toolchains(
     "@devinfra//bazel/git-toolchain:git_macos_x86_toolchain",
     "@devinfra//bazel/git-toolchain:git_macos_arm64_toolchain",
     "@devinfra//bazel/git-toolchain:git_windows_toolchain",
+    "//tools:dummy_cc_toolchain_impl",
 )

packages/angular/ssr/BUILD.bazel

@@ -1,6 +1,5 @@
 load("@devinfra//bazel/api-golden:index.bzl", "api_golden_test_npm_package")
 load("@npm//:defs.bzl", "npm_link_all_packages")
-load("@rules_pkg//:pkg.bzl", "pkg_tar")
 load("//tools:defaults.bzl", "ng_package", "ts_project")
 
 package(default_visibility = ["//visibility:public"])
@@ -77,11 +76,11 @@ ng_package(
     ],
 )
 
-pkg_tar(
+genrule(
     name = "npm_package_archive",
     srcs = [":npm_package"],
-    extension = "tgz",
-    strip_prefix = "./npm_package",
+    outs = ["npm_package_archive.tgz"],
+    cmd = "tar -czf $@ -C $(location :npm_package) .",
     # should not be built unless it is a dependency of another rule
     tags = ["manual"],
 )

tools/BUILD.bazel

@@ -1,4 +1,6 @@
+load("@rules_cc//cc:defs.bzl", "cc_toolchain")
 load("//tools:defaults.bzl", "js_binary")
+load(":dummy_cc_toolchain.bzl", "dummy_cc_toolchain_config")
 
 package(default_visibility = ["//visibility:public"])
 
@@ -30,3 +32,31 @@ js_binary(
     ],
     entry_point = "quicktype_runner.js",
 )
+
+dummy_cc_toolchain_config(name = "dummy_config")
+
+filegroup(name = "empty")
+
+cc_toolchain(
+    name = "dummy_cc_toolchain",
+    all_files = ":empty",
+    compiler_files = ":empty",
+    dwp_files = ":empty",
+    linker_files = ":empty",
+    objcopy_files = ":empty",
+    strip_files = ":empty",
+    supports_param_files = 0,
+    toolchain_config = ":dummy_config",
+    toolchain_identifier = "dummy-toolchain",
+)
+
+toolchain(
+    name = "dummy_cc_toolchain_impl",
+    exec_compatible_with = [],
+    target_compatible_with = [
+        "@platforms//os:windows",
+        "@platforms//cpu:x86_64",
+    ],
+    toolchain = ":dummy_cc_toolchain",
+    toolchain_type = "@rules_cc//cc:toolchain_type",
+)

tools/bazel/npm_package.bzl

@@ -3,7 +3,6 @@ load("@aspect_bazel_lib//lib:expand_template.bzl", "expand_template")
 load("@aspect_bazel_lib//lib:jq.bzl", "jq")
 load("@aspect_bazel_lib//lib:utils.bzl", "to_label")
 load("@aspect_rules_js//npm:defs.bzl", _npm_package = "npm_package")
-load("@rules_pkg//:pkg.bzl", "pkg_tar")
 load("//tools:link_package_json_to_tarballs.bzl", "link_package_json_to_tarballs")
 load("//tools:snapshot_repo_filter.bzl", "SNAPSHOT_REPO_JQ_FILTER")
 load("//tools:substitutions.bzl", "substitutions")
@@ -115,10 +114,10 @@ def npm_package(
     )
 
     if pkg_json:
-        pkg_tar(
+        native.genrule(
             name = "npm_package_archive",
             srcs = [":pkg"],
-            extension = "tgz",
-            strip_prefix = "./npm_package",
+            outs = ["npm_package_archive.tgz"],
+            cmd = "tar -czf $@ -C $(location :pkg) .",
             visibility = visibility,
         )

tools/dummy_cc_toolchain.bzl

@@ -0,0 +1,28 @@
+"""
+This file defines a dummy C++ toolchain for Windows.
+It is needed to satisfy Bazel's toolchain resolution when cross-compiling for Windows on Linux.
+Some rules (e.g. rules_nodejs, js_test) or their dependencies may trigger C++ toolchain resolution
+even if no actual C++ compilation is performed for the target platform.
+Without this, the build fails with "Unable to find a CC toolchain using toolchain resolution".
+"""
+
+load("@rules_cc//cc:defs.bzl", "cc_common")
+
+def _impl(ctx):
+    return cc_common.create_cc_toolchain_config_info(
+        ctx = ctx,
+        toolchain_identifier = "dummy-toolchain",
+        host_system_name = "local",
+        target_system_name = "local",
+        target_cpu = "x64_windows",
+        target_libc = "unknown",
+        compiler = "dummy",
+        abi_version = "unknown",
+        abi_libc_version = "unknown",
+    )
+
+dummy_cc_toolchain_config = rule(
+    implementation = _impl,
+    attrs = {},
+    provides = [CcToolchainConfigInfo],
+)