Support synthesis of SimpleParameters

Author: alexrford

ruby/ql/lib/codeql/ruby/ast/Parameter.qll

@@ -68,14 +68,12 @@ class NamedParameter extends Parameter, TNamedParameter {
 }
 
 /** A simple (normal) parameter. */
-class SimpleParameter extends NamedParameter, PatternParameter, VariablePattern, TSimpleParameter {
-  private Ruby::Identifier g;
+class SimpleParameter extends NamedParameter, PatternParameter, VariablePattern, TSimpleParameter instanceof SimpleParameterImpl {
+  final override string getName() { result = SimpleParameterImpl.super.getNameImpl() }
 
-  SimpleParameter() { this = TSimpleParameter(g) }
-
-  final override string getName() { result = g.getValue() }
-
-  final override LocalVariable getVariable() { result = TLocalVariableReal(_, _, g) }
+  final override LocalVariable getVariable() {
+    result = SimpleParameterImpl.super.getVariableImpl()
+  }
 
   final override LocalVariable getAVariable() { result = this.getVariable() }
 

ruby/ql/lib/codeql/ruby/ast/Pattern.qll

@@ -4,6 +4,7 @@ private import internal.AST
 private import internal.Pattern
 private import internal.TreeSitter
 private import internal.Variable
+private import internal.Parameter
 
 /** A pattern. */
 class Pattern extends AstNode {
@@ -15,6 +16,8 @@ class Pattern extends AstNode {
     implicitParameterAssignmentNode(toGenerated(this), _)
     or
     this = getSynthChild(any(AssignExpr ae), 0)
+    or
+    this instanceof SimpleParameterImpl
   }
 
   /** Gets a variable used in (or introduced by) this pattern. */

ruby/ql/lib/codeql/ruby/ast/internal/AST.qll

@@ -238,7 +238,10 @@ private module Cached {
     TSelfSynth(AST::AstNode parent, int i, AST::SelfVariable v) {
       mkSynthChild(SelfKind(v), parent, i)
     } or
-    TSimpleParameter(Ruby::Identifier g) { g instanceof Parameter::Range } or
+    TSimpleParameterReal(Ruby::Identifier g) { g instanceof Parameter::Range } or
+    TSimpleParameterSynth(AST::AstNode parent, int i) {
+      mkSynthChild(SimpleParameterKind(), parent, i)
+    } or
     TSimpleSymbolLiteral(Ruby::SimpleSymbol g) or
     TSingletonClass(Ruby::SingletonClass g) or
     TSingletonMethod(Ruby::SingletonMethod g) or
@@ -439,7 +442,7 @@ private module Cached {
     n = TScopeResolutionConstantAccess(result, _) or
     n = TScopeResolutionMethodCall(result, _) or
     n = TSelfReal(result) or
-    n = TSimpleParameter(result) or
+    n = TSimpleParameterReal(result) or
     n = TSimpleSymbolLiteral(result) or
     n = TSingletonClass(result) or
     n = TSingletonMethod(result) or
@@ -522,6 +525,8 @@ private module Cached {
     or
     result = TSelfSynth(parent, i, _)
     or
+    result = TSimpleParameterSynth(parent, i)
+    or
     result = TSplatExprSynth(parent, i)
     or
     result = TStmtSequenceSynth(parent, i)
@@ -730,6 +735,8 @@ class TParameter =
   TPatternParameter or TBlockParameter or THashSplatParameter or TKeywordParameter or
       TOptionalParameter or TSplatParameter or TForwardParameter;
 
+class TSimpleParameter = TSimpleParameterReal or TSimpleParameterSynth;
+
 class TPatternParameter = TSimpleParameter or TTuplePatternParameter;
 
 class TNamedParameter =

ruby/ql/lib/codeql/ruby/ast/internal/Parameter.qll

@@ -1,6 +1,7 @@
 private import codeql.ruby.AST
 private import AST
 private import TreeSitter
+private import Variable
 
 module Parameter {
   class Range extends Ruby::AstNode {
@@ -17,3 +18,27 @@ module Parameter {
     int getPosition() { result = pos }
   }
 }
+
+abstract class SimpleParameterImpl extends AstNode, TSimpleParameter {
+  abstract LocalVariable getVariableImpl();
+
+  abstract string getNameImpl();
+}
+
+private class SimpleParameterRealImpl extends SimpleParameterImpl, TSimpleParameterReal {
+  private Ruby::Identifier g;
+
+  SimpleParameterRealImpl() { this = TSimpleParameterReal(g) }
+
+  override LocalVariable getVariableImpl() { result = TLocalVariableReal(_, _, g) }
+
+  override string getNameImpl() { result = g.getValue() }
+}
+
+private class SimpleParameterSynthImpl extends SimpleParameterImpl, TSimpleParameterSynth {
+  SimpleParameterSynthImpl() { this = TSimpleParameterSynth(_, _) }
+
+  override LocalVariable getVariableImpl() { result = TLocalVariableSynth(this, _) }
+
+  override string getNameImpl() { result = this.getVariableImpl().getName() }
+}

ruby/ql/lib/codeql/ruby/ast/internal/Synthesis.qll

@@ -33,6 +33,7 @@ newtype SynthKind =
   MulExprKind() or
   RangeLiteralKind(boolean inclusive) { inclusive in [false, true] } or
   RShiftExprKind() or
+  SimpleParameterKind() or
   SplatExprKind() or
   StmtSequenceKind() or
   SelfKind(SelfVariable v) or