JS: Port tutorial query3

Author: asgerf

javascript/ql/test/tutorials/Analyzing data flow in JavaScript/Global data flow/query3.ql

@@ -1,30 +1,30 @@
 import javascript
 
-class CheckPathSanitizerGuard extends TaintTracking::SanitizerGuardNode, DataFlow::CallNode {
+class CheckPathSanitizerGuard extends DataFlow::CallNode {
   CheckPathSanitizerGuard() { this.getCalleeName() = "checkPath" }
 
-  override predicate sanitizes(boolean outcome, Expr e) {
+  predicate blocksExpr(boolean outcome, Expr e) {
     outcome = true and
     e = this.getArgument(0).asExpr()
   }
 }
 
-class CommandLineFileNameConfiguration extends TaintTracking::Configuration {
-  CommandLineFileNameConfiguration() { this = "CommandLineFileNameConfiguration" }
-
-  override predicate isSource(DataFlow::Node source) {
+module CommandLineFileNameConfig implements DataFlow::ConfigSig {
+  predicate isSource(DataFlow::Node source) {
     DataFlow::globalVarRef("process").getAPropertyRead("argv").getAPropertyRead() = source
   }
 
-  override predicate isSink(DataFlow::Node sink) {
+  predicate isSink(DataFlow::Node sink) {
     DataFlow::moduleMember("fs", "readFile").getACall().getArgument(0) = sink
   }
 
-  override predicate isSanitizerGuard(TaintTracking::SanitizerGuardNode nd) {
-    nd instanceof CheckPathSanitizerGuard
+  predicate isBarrier(DataFlow::Node node) {
+    node = DataFlow::MakeBarrierGuard<CheckPathSanitizerGuard>::getABarrierNode()
   }
 }
 
-from CommandLineFileNameConfiguration cfg, DataFlow::Node source, DataFlow::Node sink
-where cfg.hasFlow(source, sink)
+module CommandLineFileNameFlow = TaintTracking::Global<CommandLineFileNameConfig>;
+
+from DataFlow::Node source, DataFlow::Node sink
+where CommandLineFileNameFlow::flow(source, sink)
 select source, sink