Test: Don't expect 'Source' tag when source and alert are on same line

Previously the Source tag was required if the source and alert did not
have the exact same location. This relaxes the restriction to being on
the same line.

Note that in order to be "on the same line" both start and end lines
have to match.

It's still possible for a given line to expect both Alert and Source
tags, in case the source pairs up with another alert on a different
line.

Author: asgerf

shared/util/codeql/util/test/InlineExpectationsTest.qll

@@ -645,6 +645,29 @@ module TestPostProcessing {
     private import InlineExpectationsTest as InlineExpectationsTest
     private import InlineExpectationsTest::Make<Input>
 
+    bindingset[loc]
+    private predicate parseLocation(
+      string loc, string file, int startLine, int startColumn, int endLine, int endColumn
+    ) {
+      exists(string regexp |
+        regexp = "(.*):(-?\\d+):(-?\\d+):(-?\\d+):(-?\\d+)" and
+        file = loc.regexpCapture(regexp, 1) and
+        startLine = loc.regexpCapture(regexp, 2).toInt() and
+        startColumn = loc.regexpCapture(regexp, 3).toInt() and
+        endLine = loc.regexpCapture(regexp, 4).toInt() and
+        endColumn = loc.regexpCapture(regexp, 5).toInt()
+      )
+    }
+
+    /** Holds if the given location strings refer to the same lines, but possibly with different column numbers. */
+    bindingset[loc1, loc2]
+    private predicate sameLineInfo(string loc1, string loc2) {
+      exists(string file, int line1, int line2 |
+        parseLocation(loc1, file, line1, _, line2, _) and
+        parseLocation(loc2, file, line1, _, line2, _)
+      )
+    }
+
     /**
      * Gets the tag to be used for the path-problem source at result row `row`.
      *
@@ -653,8 +676,10 @@ module TestPostProcessing {
      */
     private string getSourceTag(int row) {
       getQueryKind() = "path-problem" and
-      exists(string loc | queryResults(mainResultSet(), row, 2, loc) |
-        if queryResults(mainResultSet(), row, 0, loc) then result = "Alert" else result = "Source"
+      exists(string sourceLoc, string selectLoc |
+        queryResults(mainResultSet(), row, 0, selectLoc) and
+        queryResults(mainResultSet(), row, 2, sourceLoc) and
+        if sameLineInfo(selectLoc, sourceLoc) then result = "Alert" else result = "Source"
       )
     }