Ruby: add CasePattern classes to CfgNodes

Author: aibaars

ruby/ql/lib/codeql/ruby/ast/Pattern.qll

@@ -99,7 +99,7 @@ private class TPattern =
 class CasePattern extends AstNode, TPattern {
   CasePattern() {
     casePattern(toGenerated(this)) or
-    this = any(HashPattern p).getValue(_)
+    synthChild(any(HashPattern p), _, this)
   }
 }
 
@@ -270,7 +270,7 @@ class HashPattern extends CasePattern, THashPattern {
   StringlikeLiteral getKey(int n) { toGenerated(result) = this.keyValuePair(n).getKey() }
 
   /** Gets the value of the `n`th pair. */
-  AstNode getValue(int n) {
+  CasePattern getValue(int n) {
     toGenerated(result) = this.keyValuePair(n).getValue() or
     synthChild(this, n, result)
   }
@@ -387,6 +387,7 @@ class ParenthesizedPattern extends CasePattern, TParenthesizedPattern {
 
   ParenthesizedPattern() { this = TParenthesizedPattern(g) }
 
+  /** Gets the underlying pattern. */
   final CasePattern getPattern() { toGenerated(result) = g.getChild() }
 
   final override string getAPrimaryQlClass() { result = "ParenthesizedPattern" }

ruby/ql/lib/codeql/ruby/controlflow/CfgNodes.qll

@@ -65,16 +65,16 @@ class ExitNode extends CfgNode, TExitNode {
  */
 class AstCfgNode extends CfgNode, TElementNode {
   private Splits splits;
-  private AstNode n;
+  AstNode e;
 
-  AstCfgNode() { this = TElementNode(_, n, splits) }
+  AstCfgNode() { this = TElementNode(_, e, splits) }
 
-  final override AstNode getNode() { result = n }
+  final override AstNode getNode() { result = e }
 
-  override Location getLocation() { result = n.getLocation() }
+  override Location getLocation() { result = e.getLocation() }
 
   final override string toString() {
-    exists(string s | s = n.toString() |
+    exists(string s | s = e.toString() |
       result = "[" + this.getSplitsString() + "] " + s
       or
       not exists(this.getSplitsString()) and result = s
@@ -93,7 +93,7 @@ class AstCfgNode extends CfgNode, TElementNode {
 
 /** A control-flow node that wraps an AST expression. */
 class ExprCfgNode extends AstCfgNode {
-  Expr e;
+  override Expr e;
 
   ExprCfgNode() { e = this.getNode() }
 
@@ -410,7 +410,7 @@ module ExprNodes {
 
   /** A control-flow node that wraps an `InClause` AST expression. */
   class InClauseCfgNode extends AstCfgNode {
-    private InClauseChildMapping e;
+    override InClauseChildMapping e;
 
     /**
      * Gets the pattern in this `in`-clause.
@@ -430,12 +430,136 @@ module ExprNodes {
 
   /** A control-flow node that wraps a `WhenClause` AST expression. */
   class WhenClauseCfgNode extends AstCfgNode {
-    private WhenClauseChildMapping e;
+    override WhenClauseChildMapping e;
 
     /** Gets the body of this `when`-clause. */
     final ExprCfgNode getBody() { e.hasCfgChild(e.getBody(), this, result) }
   }
 
+  /** A control-flow node that wraps a `CasePattern`. */
+  class CasePatternCfgNode extends AstCfgNode {
+    override CasePattern e;
+  }
+
+  private class ArrayPatternChildMapping extends NonExprChildMapping, ArrayPattern {
+    override predicate relevantChild(AstNode e) {
+      e = this.getPrefixElement(_) or
+      e = this.getSuffixElement(_) or
+      e = this.getRestVariableAccess()
+    }
+  }
+
+  /** A control-flow node that wraps a `ArrayPattern` node. */
+  class ArrayPatternCfgNode extends CasePatternCfgNode {
+    override ArrayPatternChildMapping e;
+
+    /** Gets the `n`th element of this list pattern's prefix. */
+    final CasePatternCfgNode getPrefixElement(int n) {
+      e.hasCfgChild(e.getPrefixElement(n), this, result)
+    }
+
+    /** Gets the `n`th element of this list pattern's suffix. */
+    final CasePatternCfgNode getSuffixElement(int n) {
+      e.hasCfgChild(e.getSuffixElement(n), this, result)
+    }
+
+    /** Gets the variable of the rest token, if any. */
+    final VariableWriteAccessCfgNode getRestVariableAccess() {
+      e.hasCfgChild(e.getRestVariableAccess(), this, result)
+    }
+  }
+
+  private class FindPatternChildMapping extends NonExprChildMapping, FindPattern {
+    override predicate relevantChild(AstNode e) {
+      e = this.getElement(_) or
+      e = this.getPrefixVariableAccess() or
+      e = this.getSuffixVariableAccess()
+    }
+  }
+
+  /** A control-flow node that wraps a `FindPattern` node. */
+  class FindPatternCfgNode extends CasePatternCfgNode {
+    override FindPatternChildMapping e;
+
+    /** Gets the `n`th element of this find pattern. */
+    final CasePatternCfgNode getElement(int n) { e.hasCfgChild(e.getElement(n), this, result) }
+
+    /** Gets the variable for the prefix of this list pattern, if any. */
+    final VariableWriteAccessCfgNode getPrefixVariableAccess() {
+      e.hasCfgChild(e.getPrefixVariableAccess(), this, result)
+    }
+
+    /** Gets the variable for the suffix of this list pattern, if any. */
+    final VariableWriteAccessCfgNode getSuffixVariableAccess() {
+      e.hasCfgChild(e.getSuffixVariableAccess(), this, result)
+    }
+  }
+
+  private class HashPatternChildMapping extends NonExprChildMapping, HashPattern {
+    override predicate relevantChild(AstNode e) {
+      e = this.getValue(_) or
+      e = this.getRestVariableAccess()
+    }
+  }
+
+  /** A control-flow node that wraps a `HashPattern` node. */
+  class HashPatternCfgNode extends CasePatternCfgNode {
+    override HashPatternChildMapping e;
+
+    /** Gets the value of the `n`th pair. */
+    final CasePatternCfgNode getValue(int n) { e.hasCfgChild(e.getValue(n), this, result) }
+
+    /** Gets the variable of the keyword rest token, if any. */
+    final VariableWriteAccessCfgNode getRestVariableAccess() {
+      e.hasCfgChild(e.getRestVariableAccess(), this, result)
+    }
+  }
+
+  private class AlternativePatternChildMapping extends NonExprChildMapping, AlternativePattern {
+    override predicate relevantChild(AstNode e) { e = this.getAnAlternative() }
+  }
+
+  /** A control-flow node that wraps a `AlternativePattern` node. */
+  class AlternativePatternCfgNode extends CasePatternCfgNode {
+    override AlternativePatternChildMapping e;
+
+    /** Gets the `n`th alternative. */
+    final CasePatternCfgNode getAlternative(int n) {
+      e.hasCfgChild(e.getAlternative(n), this, result)
+    }
+  }
+
+  private class AsPatternChildMapping extends NonExprChildMapping, AsPattern {
+    override predicate relevantChild(AstNode e) {
+      e = this.getPattern() or e = this.getVariableAccess()
+    }
+  }
+
+  /** A control-flow node that wraps a `AsPattern` node. */
+  class AsPatternCfgNode extends CasePatternCfgNode {
+    override AsPatternChildMapping e;
+
+    /** Gets the underlying pattern. */
+    final CasePatternCfgNode getPattern() { e.hasCfgChild(e.getPattern(), this, result) }
+
+    /** Gets the variable access for this pattern. */
+    final VariableWriteAccessCfgNode getVariableAccess() {
+      e.hasCfgChild(e.getVariableAccess(), this, result)
+    }
+  }
+
+  private class ParenthesizedPatternChildMapping extends NonExprChildMapping, ParenthesizedPattern {
+    override predicate relevantChild(AstNode e) { e = this.getPattern() }
+  }
+
+  /** A control-flow node that wraps a `ParenthesizedPattern` node. */
+  class ParenthesizedPatternCfgNode extends CasePatternCfgNode {
+    override ParenthesizedPatternChildMapping e;
+
+    /** Gets the underlying pattern. */
+    final CasePatternCfgNode getPattern() { e.hasCfgChild(e.getPattern(), this, result) }
+  }
+
   private class ConditionalExprChildMapping extends ExprChildMapping, ConditionalExpr {
     override predicate relevantChild(AstNode n) { n = [this.getCondition(), this.getBranch(_)] }
   }
@@ -533,6 +657,13 @@ module ExprNodes {
     final override VariableReadAccess getExpr() { result = ExprCfgNode.super.getExpr() }
   }
 
+  /** A control-flow node that wraps a `VariableWriteAccess` AST expression. */
+  class VariableWriteAccessCfgNode extends ExprCfgNode {
+    override VariableWriteAccess e;
+
+    final override VariableWriteAccess getExpr() { result = ExprCfgNode.super.getExpr() }
+  }
+
   /** A control-flow node that wraps a `InstanceVariableWriteAccess` AST expression. */
   class InstanceVariableWriteAccessCfgNode extends ExprCfgNode {
     override InstanceVariableWriteAccess e;