Java: PrintAst: Add synthetic nodes for other declarations

Author: joefarebrother

java/ql/src/semmle/code/java/PrintAst.qll

@@ -114,6 +114,9 @@ private predicate locationSortKeys(Element ast, string file, int line, int colum
 private newtype TPrintAstNode =
   TElementNode(Element el) { shouldPrint(el, _) } or
   TForInitNode(ForStmt fs) { shouldPrint(fs, _) and exists(fs.getAnInit()) } or
+  TLocalVarDeclNode(LocalVariableDeclExpr lvde) {
+    shouldPrint(lvde, _) and lvde.getParent() instanceof LocalVarDeclParent
+  } or
   TAnnotationsNode(Annotatable ann) {
     shouldPrint(ann, _) and ann.hasAnnotation() and not partOfAnnotation(ann)
   } or
@@ -330,6 +333,46 @@ final class ForStmtNode extends ExprStmtNode {
   }
 }
 
+/**
+ * An element that can be the parent of a `LocalVariableDeclExpr` for which we want
+ * to use a synthetic node to hold the variable declaration and its `TypeAccess`.
+ */
+private class LocalVarDeclParent extends ExprOrStmt {
+  LocalVarDeclParent() {
+    this instanceof EnhancedForStmt or
+    this instanceof CatchClause or
+    this.(InstanceOfExpr).isPattern()
+  }
+
+  /** Gets the variable declaration that this element contains */
+  LocalVariableDeclExpr getVariable() { result.getParent() = this }
+
+  /** Gets the type access of the variable */
+  Expr getTypeAccess() { result = getVariable().getTypeAccess() }
+}
+
+/**
+ * A node representing an element that can be the parent of a `LocalVariableDeclExpr` for which we
+ * want to use a synthetic node to variable declaration and its type access.
+ *
+ * Excludes:
+ * - `LocalVariableDeclStmt` because a synthetic node isn't needed
+ * - `ForStmt` becasue a different synthetic node is already used
+ */
+final class LocalVarDeclParentNode extends ExprStmtNode {
+  LocalVarDeclParent lvdp;
+
+  LocalVarDeclParentNode() { lvdp = element }
+
+  override PrintAstNode getChild(int childIndex) {
+    result = super.getChild(childIndex) and
+    not result.(ElementNode).getElement() = [lvdp.getVariable(), lvdp.getTypeAccess()]
+    or
+    childIndex = lvdp.getVariable().getIndex() and
+    result.(LocalVarDeclSynthNode).getVariable() = lvdp.getVariable()
+  }
+}
+
 /**
  * A node representing a `Callable`, such as method declaration.
  */
@@ -509,6 +552,30 @@ final class ForInitNode extends PrintAstNode, TForInitNode {
   ForStmt getForStmt() { result = fs }
 }
 
+/**
+ * A synthetic node holding a `LocalVariableDeclExpr` and its type access.
+ */
+final class LocalVarDeclSynthNode extends PrintAstNode, TLocalVarDeclNode {
+  LocalVariableDeclExpr lvde;
+
+  LocalVarDeclSynthNode() { this = TLocalVarDeclNode(lvde) }
+
+  override string toString() { result = "(Local Variable Declaration)" }
+
+  override ElementNode getChild(int childIndex) {
+    childIndex = 0 and
+    result.getElement() = lvde.getTypeAccess()
+    or
+    childIndex = 1 and
+    result.getElement() = lvde
+  }
+
+  /**
+   * Gets the underlying `LocalVariableDeclExpr`
+   */
+  LocalVariableDeclExpr getVariable() { result = lvde }
+}
+
 /**
  * A node representing the annotations of an `Annotatable`.
  * Only rendered if there is at least one annotation.

java/ql/test/library-tests/java7/MultiCatch/PrintAst.expected

@@ -21,10 +21,11 @@ MultiCatch.java:
 #   14|                 0: [ClassInstanceExpr] new SQLException(...)
 #   14|                   -3: [TypeAccess] SQLException
 #   15|           0: [CatchClause] stmt
-#   15|             -1: [UnionTypeAccess] ...|...
-#   15|               0: [TypeAccess] IOException
-#   15|               1: [TypeAccess] SQLException
-#   15|             0: [LocalVariableDeclExpr] e
+#-----|             0: (Local Variable Declaration)
+#   15|               0: [UnionTypeAccess] ...|...
+#   15|                 0: [TypeAccess] IOException
+#   15|                 1: [TypeAccess] SQLException
+#   15|               1: [LocalVariableDeclExpr] e
 #   16|             1: [BlockStmt] stmt
 #   17|               0: [ExprStmt] stmt
 #   17|                 0: [MethodAccess] printStackTrace(...)
@@ -55,10 +56,11 @@ MultiCatch.java:
 #   30|               0: [ClassInstanceExpr] new Exception(...)
 #   30|                 -3: [TypeAccess] Exception
 #   31|           0: [CatchClause] stmt
-#   31|             -1: [UnionTypeAccess] ...|...
-#   31|               0: [TypeAccess] IOException
-#   31|               1: [TypeAccess] SQLException
-#   31|             0: [LocalVariableDeclExpr] e
+#-----|             0: (Local Variable Declaration)
+#   31|               0: [UnionTypeAccess] ...|...
+#   31|                 0: [TypeAccess] IOException
+#   31|                 1: [TypeAccess] SQLException
+#   31|               1: [LocalVariableDeclExpr] e
 #   32|             1: [BlockStmt] stmt
 #   35|     4: [Method] ordinaryCatch
 #   35|       3: [TypeAccess] void
@@ -69,6 +71,7 @@ MultiCatch.java:
 #   39|               0: [ClassInstanceExpr] new IOException(...)
 #   39|                 -3: [TypeAccess] IOException
 #   40|           0: [CatchClause] stmt
-#   40|             -1: [TypeAccess] Exception
-#   40|             0: [LocalVariableDeclExpr] e
+#-----|             0: (Local Variable Declaration)
+#   40|               0: [TypeAccess] Exception
+#   40|               1: [LocalVariableDeclExpr] e
 #   41|             1: [BlockStmt] stmt