Merge pull request #1649 from ian-semmle/constexpr_if

C++: Add 'constexpr if' support

Author: nickrolfe

cpp/ql/src/semmle/code/cpp/stmts/Stmt.qll

@@ -294,6 +294,84 @@ class IfStmt extends ConditionalStmt, @stmt_if {
   }
 }
 
+/**
+ * A C/C++ 'constexpr if' statement.
+ */
+class ConstexprIfStmt extends ConditionalStmt, @stmt_constexpr_if {
+
+  /**
+   * Gets the condition expression of this 'constexpr if' statement.
+   *
+   * For example, for
+   * ```
+   * if constexpr (b) { x = 1; }
+   * ```
+   * the result is `b`.
+   */
+  Expr getCondition() { result = this.getChild(0) }
+
+  override Expr getControllingExpr() { result = this.getCondition() }
+
+  /**
+   * Gets the 'then' statement of this 'constexpr if' statement.
+   *
+   * For example, for
+   * ```
+   * if constexpr (b) { x = 1; }
+   * ```
+   * the result is the `Block` `{ x = 1; }`.
+   */
+  Stmt getThen() { constexpr_if_then(underlyingElement(this), unresolveElement(result)) }
+
+  /**
+   * Gets the 'else' statement of this 'constexpr if' statement, if any.
+   *
+   * For example, for
+   * ```
+   * if constexpr (b) { x = 1; } else { x = 2; }
+   * ```
+   * the result is the `Block` `{ x = 2; }`, and for
+   * ```
+   * if constexpr (b) { x = 1; }
+   * ```
+   * there is no result.
+   */
+  Stmt getElse() { constexpr_if_else(underlyingElement(this), unresolveElement(result)) }
+
+  /**
+   * Holds if this 'constexpr if' statement has an 'else' statement.
+   *
+   * For example, this holds for
+   * ```
+   * if constexpr (b) { x = 1; } else { x = 2; }
+   * ```
+   * but not for
+   * ```
+   * if constexpr (b) { x = 1; }
+   * ```
+   */
+  predicate hasElse() { exists(Stmt s | this.getElse() = s) }
+
+  override string toString() { result = "if constexpr (...) ... " }
+
+  override predicate mayBeImpure() {
+    this.getCondition().mayBeImpure() or
+    this.getThen().mayBeImpure() or
+    this.getElse().mayBeImpure()
+  }
+  override predicate mayBeGloballyImpure() {
+    this.getCondition().mayBeGloballyImpure() or
+    this.getThen().mayBeGloballyImpure() or
+    this.getElse().mayBeGloballyImpure()
+  }
+
+  override MacroInvocation getGeneratingMacro() {
+    result.getAnExpandedElement() = this.getCondition() and
+    this.getThen().getGeneratingMacro() = result and
+    (this.hasElse() implies this.getElse().getGeneratingMacro() = result)
+  }
+}
+
 /**
  * A C/C++ loop, that is, either a 'while' loop, a 'for' loop, or a
  * 'do' loop.

cpp/ql/src/semmlecode.cpp.dbscheme

@@ -1639,6 +1639,7 @@ case @stmt.kind of
 // ...  32 @stmt_at_synchronized deprecated
 |  33 = @stmt_handler
 // ...  34 @stmt_finally_end deprecated
+|  35 = @stmt_constexpr_if
 ;
 
 type_vla(
@@ -1661,6 +1662,16 @@ if_else(
     int else_id: @stmt ref
 );
 
+constexpr_if_then(
+    unique int constexpr_if_stmt: @stmt_constexpr_if ref,
+    int then_id: @stmt ref
+);
+
+constexpr_if_else(
+    unique int constexpr_if_stmt: @stmt_constexpr_if ref,
+    int else_id: @stmt ref
+);
+
 while_body(
     unique int while_stmt: @stmt_while ref,
     int body_id: @stmt ref