C++: Fix inconsistent-loop-direction performance

This query seems to have been de-optimized by recent optimizer or stats
changes. On libretro/libretro-uae, the query took 1 second on a warm
cache with dist 89ad5f1 but took 9979 seconds with dist a3b9b6eb9.

The slowness was due to a Cartesian product in
`illDefined{Decr,Incr}ForStmt` between all the definitions and all the
uses of `Variable v`. This would be no problem with the right join
order, but that has apparently been lost. This commit factors out a pair
of `pragma[noinline]` helper predicates to make sure the definitions
(`v.getAnAssignedValue()`) and the uses (`v.getAnAccess()`) are queried
and filtered in separate predicates.

The performance problem can be seen in the tuple counts of this pipeline
I interrupted during evaluation of
`inconsistentLoopDirection::illDefinedDecrForStmt#ffff#shared`:

    89716     ~3%     {2} r1 = SCAN Variable::Variable::getAnAssignedValue_dispred#ff OUTPUT FIELDS {Variable::Variable::getAnAssignedValue_dispred#ff.<1>,Variable::Variable::getAnAssignedValue_dispred#ff.<0>}
    89716     ~0%     {3} r2 = JOIN r1 WITH DataFlowUtil::TExprNode#ff@staged_ext ON r1.<0>=DataFlowUtil::TExprNode#ff@staged_ext.<0> OUTPUT FIELDS {r1.<1>,DataFlowUtil::TExprNode#ff@staged_ext.<0>,DataFlowUtil::TExprNode#ff@staged_ext.<1>}
    502539405 ~0%     {4} r3 = JOIN r2 WITH Variable::Variable::getAnAccess_dispred#fb ON r2.<0>=Variable::Variable::getAnAccess_dispred#fb.<0> OUTPUT FIELDS {Variable::Variable::getAnAccess_dispred#fb.<1>,r2.<1>,r2.<2>,r2.<0>}
                      return r3

Author: jbj

cpp/ql/src/Likely Bugs/Likely Typos/inconsistentLoopDirection.ql

@@ -23,18 +23,26 @@ predicate candidateForStmt(ForStmt forStmt, Variable v, CrementOperation update,
   rel = forStmt.getCondition()
 }
 
-predicate illDefinedDecrForStmt( ForStmt forstmt, Variable v, Expr initialCondition, Expr terminalCondition ) {
-  exists(DecrementOperation dec, RelationalOperation rel |
-    // decrementing for loop
-    candidateForStmt(forstmt, v, dec, rel) and
+pragma[noinline]
+predicate candidateDecrForStmt(ForStmt forStmt, Variable v, VariableAccess lesserOperand, Expr terminalCondition) {
+  exists(DecrementOperation update, RelationalOperation rel |
+    candidateForStmt(forStmt, v, update, rel) and
 
     // condition is `v < terminalCondition`
     terminalCondition = rel.getGreaterOperand() and
-    v.getAnAccess() = rel.getLesserOperand() and
+    lesserOperand = rel.getLesserOperand() and
+    v.getAnAccess() = lesserOperand
+  )
+}
+
+predicate illDefinedDecrForStmt( ForStmt forstmt, Variable v, Expr initialCondition, Expr terminalCondition ) {
+  exists(VariableAccess lesserOperand |
+    // decrementing for loop
+    candidateDecrForStmt(forstmt, v, lesserOperand, terminalCondition) and
 
     // `initialCondition` is a value of `v` in the for loop
     v.getAnAssignedValue() = initialCondition and
-    DataFlow::localFlowStep(DataFlow::exprNode(initialCondition), DataFlow::exprNode(rel.getLesserOperand())) and
+    DataFlow::localFlowStep(DataFlow::exprNode(initialCondition), DataFlow::exprNode(lesserOperand)) and
 
     // `initialCondition` < `terminalCondition`
     (
@@ -45,18 +53,26 @@ predicate illDefinedDecrForStmt( ForStmt forstmt, Variable v, Expr initialCondit
   )
 }
 
-predicate illDefinedIncrForStmt( ForStmt forstmt, Variable v, Expr initialCondition, Expr terminalCondition ) {
-  exists(IncrementOperation inc, RelationalOperation rel |
-    // incrementing for loop
-    candidateForStmt(forstmt, v, inc, rel) and
+pragma[noinline]
+predicate candidateIncrForStmt(ForStmt forStmt, Variable v, VariableAccess greaterOperand, Expr terminalCondition) {
+  exists(IncrementOperation update, RelationalOperation rel |
+    candidateForStmt(forStmt, v, update, rel) and
 
     // condition is `v > terminalCondition`
     terminalCondition = rel.getLesserOperand() and
-    v.getAnAccess() = rel.getGreaterOperand() and
+    greaterOperand = rel.getGreaterOperand() and
+    v.getAnAccess() = greaterOperand
+  )
+}
+
+predicate illDefinedIncrForStmt( ForStmt forstmt, Variable v, Expr initialCondition, Expr terminalCondition ) {
+  exists(VariableAccess greaterOperand |
+    // incrementing for loop
+    candidateIncrForStmt(forstmt, v, greaterOperand, terminalCondition) and
 
     // `initialCondition` is a value of `v` in the for loop
     v.getAnAssignedValue() = initialCondition and
-    DataFlow::localFlowStep(DataFlow::exprNode(initialCondition), DataFlow::exprNode(rel.getGreaterOperand())) and
+    DataFlow::localFlowStep(DataFlow::exprNode(initialCondition), DataFlow::exprNode(greaterOperand)) and
 
     // `terminalCondition` < `initialCondition`
     (