Python: Make exception info concept local

Author: yoff

python/ql/src/semmle/python/Concepts.qll

@@ -293,54 +293,6 @@ module SqlExecution {
   }
 }
 
-/**
- * A data-flow node that carries information about an error. Such information should
- * rarely be exposed directly to the user.
- *
- * Extend this class to refine existing API models. If you want to model new APIs,
- * extend `ErrorInfoSource::Range` instead.
- */
-class ErrorInfoSource extends DataFlow::Node {
-  ErrorInfoSource::Range range;
-
-  ErrorInfoSource() { this = range }
-}
-
-/** Provides a class for modeling new sources of error information, say via APIs. */
-module ErrorInfoSource {
-  /**
-   * A data-flow node that carries information about an error. Such information should
-   * rarely be exposed directly to the user.
-   *
-   * Extend this class to model new APIs. If you want to refine existing API models,
-   * extend `ErrorInfoSource` instead.
-   */
-  abstract class Range extends DataFlow::Node { }
-}
-
-/**
- * A data-flow node that represents the creation or introduction of an exception.
- *
- * Extend this class to refine existing API models. If you want to model new APIs,
- * extend `ExceptionSource::Range` instead.
- */
-class ExceptionSource extends ErrorInfoSource::Range {
-  ExceptionSource::Range range;
-
-  ExceptionSource() { this = range }
-}
-
-/** Provides a class for modeling new sources of exceptions, say via APIs. */
-module ExceptionSource {
-  /**
-   * A data-flow node that represents the creation or introduction of an exception.
-   *
-   * Extend this class to model new APIs. If you want to refine existing API models,
-   * extend `ExceptionSource` instead.
-   */
-  abstract class Range extends DataFlow::Node { }
-}
-
 /** Provides classes for modeling HTTP-related APIs. */
 module HTTP {
   import semmle.python.web.HttpConstants

python/ql/src/semmle/python/frameworks/Stdlib.qll

@@ -1657,33 +1657,6 @@ private module Stdlib {
   class Sqlite3 extends PEP249Module {
     Sqlite3() { this = sqlite3() }
   }
-
-  // ---------------------------------------------------------------------------
-  // traceback
-  // ---------------------------------------------------------------------------
-  /** Provides models for the `traceback` module. */
-  module traceback {
-    private class TracebackFunctionCall extends ErrorInfoSource::Range, DataFlow::CallCfgNode {
-      TracebackFunctionCall() {
-        this =
-          API::moduleImport("traceback")
-              .getMember([
-                  "extract_tb", "extract_stack", "format_list", "format_exception_only",
-                  "format_exception", "format_exc", "format_tb", "format_stack"
-                ])
-              .getACall()
-      }
-    }
-  }
-}
-
-private class CaughtException extends ExceptionSource::Range {
-  CaughtException() { this.asExpr() = any(ExceptStmt s).getName() }
-}
-
-/** A call to `sys.exc_info` */
-private class SysExcInfoCall extends ErrorInfoSource::Range, DataFlow::CallCfgNode {
-  SysExcInfoCall() { this = API::moduleImport("sys").getMember("exc_info").getACall() }
 }
 
 // ---------------------------------------------------------------------------

python/ql/src/semmle/python/security/dataflow/ExceptionInfo.qll

@@ -0,0 +1,34 @@
+/** Provides classes representing various sources of information about raised exceptions. */
+
+import python
+import semmle.python.dataflow.new.DataFlow
+private import semmle.python.ApiGraphs
+
+/**
+ * A data-flow node that carries information about a raised exception.
+ * Such information should rarely be exposed directly to the user.
+ */
+abstract class ExceptionInfo extends DataFlow::Node { }
+
+/** A call to a function from the `traceback` module revealing information about a raised exception. */
+private class TracebackFunctionCall extends ExceptionInfo, DataFlow::CallCfgNode {
+  TracebackFunctionCall() {
+    this =
+      API::moduleImport("traceback")
+          .getMember([
+              "extract_tb", "extract_stack", "format_list", "format_exception_only",
+              "format_exception", "format_exc", "format_tb", "format_stack"
+            ])
+          .getACall()
+  }
+}
+
+/** A caught exception. */
+private class CaughtException extends ExceptionInfo {
+  CaughtException() { this.asExpr() = any(ExceptStmt s).getName() }
+}
+
+/** A call to `sys.exc_info`. */
+private class SysExcInfoCall extends ExceptionInfo, DataFlow::CallCfgNode {
+  SysExcInfoCall() { this = API::moduleImport("sys").getMember("exc_info").getACall() }
+}

python/ql/src/semmle/python/security/dataflow/StackTraceExposure.qll

@@ -7,14 +7,15 @@ import python
 import semmle.python.dataflow.new.DataFlow
 import semmle.python.dataflow.new.TaintTracking
 import semmle.python.Concepts
+private import ExceptionInfo
 
 /**
  * A taint-tracking configuration for detecting stack trace exposure.
  */
 class StackTraceExposureConfiguration extends TaintTracking::Configuration {
   StackTraceExposureConfiguration() { this = "StackTraceExposureConfiguration" }
 
-  override predicate isSource(DataFlow::Node source) { source instanceof ErrorInfoSource }
+  override predicate isSource(DataFlow::Node source) { source instanceof ExceptionInfo }
 
   override predicate isSink(DataFlow::Node sink) {
     sink = any(HTTP::Server::HttpResponse response).getBody()

python/ql/test/experimental/library-tests/frameworks/django-v2-v3/manage.py

@@ -9,7 +9,7 @@ def main():
     os.environ.setdefault('DJANGO_SETTINGS_MODULE', 'testproj.settings')
     try:
         from django.core.management import execute_from_command_line
-    except ImportError as exc:  #$ errorInfoSource exceptionSource
+    except ImportError as exc:
         raise ImportError(
             "Couldn't import Django. Are you sure it's installed and "
             "available on your PYTHONPATH environment variable? Did you "

python/ql/test/experimental/library-tests/frameworks/stdlib-py3/Exceptions.py

@@ -319,35 +319,3 @@ class SafeAccessCheckTest extends InlineExpectationsTest {
     )
   }
 }
-
-class ErrorInfoSourceTest extends InlineExpectationsTest {
-  ErrorInfoSourceTest() { this = "ErrorInfoSourceTest" }
-
-  override string getARelevantTag() { result = "errorInfoSource" }
-
-  override predicate hasActualResult(Location location, string element, string tag, string value) {
-    exists(location.getFile().getRelativePath()) and
-    exists(ErrorInfoSource e |
-      location = e.getLocation() and
-      element = e.toString() and
-      value = "" and
-      tag = "errorInfoSource"
-    )
-  }
-}
-
-class ExceptionSourceTest extends InlineExpectationsTest {
-  ExceptionSourceTest() { this = "ExceptionSourceTest" }
-
-  override string getARelevantTag() { result = "exceptionSource" }
-
-  override predicate hasActualResult(Location location, string element, string tag, string value) {
-    exists(location.getFile().getRelativePath()) and
-    exists(ExceptionSource e |
-      location = e.getLocation() and
-      element = e.toString() and
-      value = "" and
-      tag = "exceptionSource"
-    )
-  }
-}

python/ql/test/experimental/library-tests/frameworks/stdlib-py3/Stacktrace.py

@@ -0,0 +1,20 @@
+import python
+import semmle.python.dataflow.new.DataFlow
+import TestUtilities.InlineExpectationsTest
+import semmle.python.security.dataflow.ExceptionInfo
+
+class ExceptionInfoTest extends InlineExpectationsTest {
+  ExceptionInfoTest() { this = "ExceptionInfoTest" }
+
+  override string getARelevantTag() { result = "exceptionInfo" }
+
+  override predicate hasActualResult(Location location, string element, string tag, string value) {
+    exists(location.getFile().getRelativePath()) and
+    exists(ExceptionInfo e |
+      location = e.getLocation() and
+      element = e.toString() and
+      value = "" and
+      tag = "exceptionInfo"
+    )
+  }
+}

python/ql/test/experimental/meta/ConceptsTest.qll

@@ -0,0 +1,10 @@
+try:
+    1+2
+except Exception as e:  #$ exceptionInfo
+    e
+
+def test_exception():
+    try:
+        1+2
+    except Exception as e:  #$ exceptionInfo
+        e