initial commit

Author: bbakerman

build.gradle

@@ -0,0 +1,133 @@
+import java.text.SimpleDateFormat
+
+buildscript {
+    repositories {
+        mavenCentral()
+    }
+}
+
+plugins {
+    id "com.jfrog.bintray" version "1.8.4"
+}
+
+apply plugin: 'java'
+apply plugin: 'groovy'
+apply plugin: 'maven-publish'
+apply plugin: 'com.jfrog.bintray'
+
+def getDevelopmentVersion() {
+    def output = new StringBuilder()
+    def error = new StringBuilder()
+    def gitShortHash = "git -C ${projectDir} rev-parse --short HEAD".execute()
+    gitShortHash.waitForProcessOutput(output, error)
+    def gitHash = output.toString().trim()
+    if (gitHash.isEmpty()) {
+        println "git hash is empty: error: ${error.toString()}"
+        throw new IllegalStateException("git hash could not be determined")
+    }
+    new SimpleDateFormat('yyyy-MM-dd\'T\'HH-mm-ss').format(new Date()) + "-" + gitHash
+}
+
+
+def releaseVersion = System.env.RELEASE_VERSION
+version = releaseVersion ? releaseVersion : getDevelopmentVersion()
+group = 'com.graphql-java'
+
+sourceCompatibility = 1.8
+targetCompatibility = 1.8
+
+repositories {
+    mavenCentral()
+    maven { url "http://dl.bintray.com/andimarek/graphql-java" }
+}
+
+
+dependencies {
+    compile "com.graphql-java:graphql-java:12.0"
+
+    testCompile 'org.spockframework:spock-core:1.1-groovy-2.4'
+    testCompile 'org.codehaus.groovy:groovy-all:2.4.13'
+}
+
+task sourcesJar(type: Jar, dependsOn: classes) {
+    classifier = 'sources'
+    from sourceSets.main.allSource
+}
+
+task javadocJar(type: Jar, dependsOn: javadoc) {
+    classifier = 'javadoc'
+    from javadoc.destinationDir
+}
+
+artifacts {
+    archives sourcesJar
+    archives javadocJar
+}
+
+publishing {
+    publications {
+        maven(MavenPublication) {
+            from components.java
+            groupId group
+            artifactId 'graphql-java-extended-validation'
+            version version
+
+            artifact sourcesJar
+            artifact javadocJar
+
+            pom.withXml {
+                asNode().children().last() + {
+                    resolveStrategy = Closure.DELEGATE_FIRST
+                    name 'graphql-java-extended-validation'
+                    description 'A library fo extended validation for graphql-java'
+                    url 'https://github.com/graphql-java/graphql-java-extended-validation'
+                    inceptionYear '2019'
+
+                    scm {
+                        url 'https://github.com/graphql-java/graphql-java-extended-validation'
+                        connection 'scm:git@github.com:graphql-java/graphql-java-extended-validation.git'
+                        developerConnection 'scm:git@github.com:graphql-java/graphql-java-extended-validation.git'
+                    }
+
+                    licenses {
+                        license {
+                            name 'MIT'
+                            url 'https://github.com/graphql-java/graphql-java/blob/master/LICENSE.md'
+                            distribution 'repo'
+                        }
+                    }
+
+                    developers {
+                        developer {
+                            id 'bbakerman'
+                            name 'Brad Baker'
+                            email 'bbakerman@gmail.com'
+                        }
+                    }
+                }
+            }
+        }
+    }
+}
+
+bintray {
+    user = System.getenv('BINTRAY_USER')
+    key = System.getenv('BINTRAY_API_KEY')
+    publications = ['maven']
+    publish = true
+    pkg {
+        userOrg = 'graphql-java'
+        repo = 'graphql-java'
+        name = "graphql-java-extended-validation"
+        desc = 'A library fo extended validation for graphql-java'
+        licenses = ['MIT']
+        vcsUrl = 'https://github.com/graphql-java/graphql-java-extended-validation.git'
+        version {
+            released = new Date()
+            vcsTag = project.version
+            gpg {
+                sign = true
+            }
+        }
+    }
+}

gradle/wrapper/gradle-wrapper.jar

@@ -0,0 +1,6 @@
+#Sat Sep 15 15:12:07 AEST 2018
+distributionBase=GRADLE_USER_HOME
+distributionPath=wrapper/dists
+zipStoreBase=GRADLE_USER_HOME
+zipStorePath=wrapper/dists
+distributionUrl=https\://services.gradle.org/distributions/gradle-4.8.1-all.zip