Add list pending organization invitations req

Author: phadej

github.cabal

@@ -79,6 +79,7 @@ Library
     GitHub.Data.Gists
     GitHub.Data.GitData
     GitHub.Data.Id
+    GitHub.Data.Invitation
     GitHub.Data.Issues
     GitHub.Data.Milestone
     GitHub.Data.Name

src/GitHub.hs

@@ -162,6 +162,7 @@ module GitHub (
     membersOfR,
     membersOfWithR,
     isMemberOfR,
+    orgInvitationsR,
 
     -- ** Teams
     -- | See <https://developer.github.com/v3/orgs/teams/>

src/GitHub/Data.hs

@@ -41,6 +41,7 @@ module GitHub.Data (
     module GitHub.Data.Events,
     module GitHub.Data.Gists,
     module GitHub.Data.GitData,
+    module GitHub.Data.Invitation,
     module GitHub.Data.Issues,
     module GitHub.Data.Milestone,
     module GitHub.Data.Options,
@@ -70,6 +71,7 @@ import GitHub.Data.Events
 import GitHub.Data.Gists
 import GitHub.Data.GitData
 import GitHub.Data.Id
+import GitHub.Data.Invitation
 import GitHub.Data.Issues
 import GitHub.Data.Milestone
 import GitHub.Data.Name

src/GitHub/Data/Invitation.hs

@@ -0,0 +1,57 @@
+-----------------------------------------------------------------------------
+-- |
+-- License     :  BSD-3-Clause
+-- Maintainer  :  Oleg Grenrus <oleg.grenrus@iki.fi>
+--
+module GitHub.Data.Invitation where
+
+import GitHub.Data.Definitions
+import GitHub.Data.Id          (Id)
+import GitHub.Data.Name        (Name)
+import GitHub.Internal.Prelude
+import Prelude ()
+
+data Invitation = Invitation
+    { invitationId        :: !(Id Invitation)
+    -- TODO: technically either one should be, maybe both. use `these` ?
+    , invitationLogin     :: !(Maybe (Name User))
+    , invitationEmail     :: !(Maybe Text)
+    , invitationRole      :: !InvitationRole
+    , invitationCreatedAt :: !UTCTime
+    , inviter             :: !SimpleUser
+    }
+  deriving (Show, Data, Typeable, Eq, Ord, Generic)
+
+instance NFData Invitation where rnf = genericRnf
+instance Binary Invitation
+
+instance FromJSON Invitation where
+    parseJSON = withObject "Invitation" $ \o -> Invitation
+        <$> o .: "id"
+        <*> o .:? "login"
+        <*> o .:? "email"
+        <*> o .: "role"
+        <*> o .: "created_at"
+        <*> o .: "inviter"
+
+
+data InvitationRole
+    = InvitationRoleDirectMember
+    | InvitationRoleAdmin
+    | InvitationRoleBillingManager
+    | InvitationRoleHiringManager
+    | InvitationRoleReinstate
+  deriving
+    (Eq, Ord, Show, Enum, Bounded, Generic, Typeable, Data)
+
+instance NFData InvitationRole where rnf = genericRnf
+instance Binary InvitationRole
+
+instance FromJSON InvitationRole where
+    parseJSON = withText "InvirationRole" $ \t -> case t of
+        "direct_member"   -> pure InvitationRoleDirectMember
+        "admin"           -> pure InvitationRoleAdmin
+        "billing_manager" -> pure InvitationRoleBillingManager
+        "hiring_manager"  -> pure InvitationRoleHiringManager
+        "reinstate"       -> pure InvitationRoleReinstate
+        _                 -> fail $ "Invalid role " ++ show t

src/GitHub/Endpoints/Organizations/Members.hs

@@ -13,6 +13,7 @@ module GitHub.Endpoints.Organizations.Members (
     isMemberOf,
     isMemberOf',
     isMemberOfR,
+    orgInvitationsR,
     module GitHub.Data,
     ) where
 
@@ -78,4 +79,10 @@ isMemberOf = isMemberOf' Nothing
 -- See <https://developer.github.com/v3/orgs/members/#check-membership>
 isMemberOfR :: Name User -> Name Organization -> Request k Bool
 isMemberOfR user org = StatusQuery statusOnlyOk $
-    Query [ "orgs", toPathPart org, "members", toPathPart user ] []
+    Query [ "orgs", toPathPart org, "members", toPathPart user ] []
+
+-- | List pending organization invitations
+--
+-- See <https://developer.github.com/v3/orgs/members/#list-pending-organization-invitations>
+orgInvitationsR :: Name Organization -> FetchCount -> Request 'RA (Vector Invitation)
+orgInvitationsR org = pagedQuery ["orgs", toPathPart org, "invitations"] []