Update publishing scripts

Author: adriangl

build.gradle

@@ -27,7 +27,6 @@ buildscript {
     dependencies {
         classpath "com.android.tools.build:gradle:7.4.2"
         classpath "org.jetbrains.kotlin:kotlin-gradle-plugin:$kotlin_version"
-        classpath "com.github.dcendents:android-maven-gradle-plugin:2.1"
         classpath "com.gladed.androidgitversion:gradle-android-git-version:0.4.14"
     }
 }

jitpack-android.gradle

@@ -0,0 +1,82 @@
+/*
+ * Copyright 2021 HyperDevs
+ *
+ * Copyright 2020 BQ
+ *
+ * Licensed under the Apache License, Version 2.0 (the "License");
+ * you may not use this file except in compliance with the License.
+ * You may obtain a copy of the License at
+ *
+ *    http://www.apache.org/licenses/LICENSE-2.0
+ *
+ * Unless required by applicable law or agreed to in writing, software
+ * distributed under the License is distributed on an "AS IS" BASIS,
+ * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+ * See the License for the specific language governing permissions and
+ * limitations under the License.
+ */
+
+apply plugin: "maven-publish"
+
+group = "com.hyperdevs"
+version = androidGitVersion.name()
+
+android {
+    publishing {
+        singleVariant("release") {
+            withSourcesJar()
+            withJavadocJar()
+        }
+    }
+}
+
+afterEvaluate {
+    publishing {
+        publications {
+            // Creates a Maven publication called "release".
+            release(MavenPublication) {
+                from components.release
+                artifactId = "appupdateshelper"
+
+                pom {
+                    name = "Android App Updates Helper"
+                    description = "This utility library aims to help Android developers to use the Google Play In-App Updates API in an easy way."
+                    url = "https://github.com/hyperdevs-team/android-app-updates-helper"
+                    version = androidGitVersion.name()
+                    inceptionYear = "2019"
+
+                    licenses {
+                        license {
+                            name = "The Apache License, Version 2.0"
+                            url = "http://www.apache.org/licenses/LICENSE-2.0.txt"
+                        }
+                    }
+
+                    organization {
+                        name = "HyperDevs"
+                        url = "https://github.com/hyperdevs-team"
+                    }
+
+                    issueManagement {
+                        system = "GitHub Issues"
+                        url = "https://github.com/hyperdevs-team/android-app-updates-helper/issues"
+                    }
+
+                    scm {
+                        connection = "git@github.com:hyperdevs-team/android-app-updates-helper.git"
+                        url = "https://github.com/hyperdevs-team/android-app-updates-helper.git"
+                    }
+
+                    developers {
+                        developer {
+                            name = "Adrián García"
+                            id = "adriangl"
+                            url = "https://github.com/adriangl"
+                            roles = ["Maintainer"]
+                        }
+                    }
+                }
+            }
+        }
+    }
+}

jitpack.yml

@@ -0,0 +1,2 @@
+jdk:
+  - openjdk11

lib/build.gradle

@@ -38,7 +38,8 @@ ext {
 }
 
 android {
-    compileSdkVersion compile_sdk_version
+    namespace = "com.hyperdevs.appupdateshelper"
+    compileSdk = compile_sdk_version
     buildToolsVersion = build_tools_version
 
     defaultConfig {
@@ -78,27 +79,5 @@ dependencies {
     androidTestImplementation "androidx.test.espresso:espresso-core:3.5.1"
 }
 
-// Build a jar with source files
-task sourcesJar(type: Jar) {
-    from android.sourceSets.main.java.srcDirs
-    archiveClassifier.set("sources")
-}
-
-// Build JavaDoc from source files
-task javadoc(type: Javadoc) {
-    failOnError false
-    source = android.sourceSets.main.java.sourceFiles
-    configurations.implementation.setCanBeResolved(true)
-    classpath += project.files(android.getBootClasspath().join(File.pathSeparator)) + configurations.implementation
-}
+apply from: "../jitpack-android.gradle"
 
-// Build a jar with JavaDoc
-task javadocJar(type: Jar, dependsOn: javadoc) {
-    archiveClassifier.set("javadoc")
-    from javadoc.destinationDir
-}
-
-artifacts {
-    archives sourcesJar
-    archives javadocJar
-}