Add IntelliJ Platform 2025.3 build (#250)

In 2025.3 IntelliJ IDEA Community and Ultimate are combined into one product.
See https://blog.jetbrains.com/platform/2025/11/intellij-platform-2025-3-what-plugin-developers-should-know/
Along with this change the build system was updated. See https://blog.jetbrains.com/platform/2025/11/intellij-platform-2025-3-what-plugin-developers-should-know/#requirements

Upgrade `org.jetbrains.intellij.platform ` plugin to 2.10.5. This leads to need more ram on GitHub Actions, so it has been increased to 1024 MB
Upgrade Gradle to 8.14.3:
- The space assignment syntax is now deprecated 
- The JVM is now configured different
- Calling `Task.getProject()` is now deprecated 
- `task` should be replaced with `tasks.register` 


Update minimal supported version to 2024.2 (224) and increased the JVM Version to 21.

Author: hduelme

.github/workflows/main.yml

@@ -8,11 +8,11 @@ jobs:
       fail-fast: false
       matrix:
         version:
-          - { jdk: 17, idea: 2024.1 }
           - { jdk: 21, idea: 2024.2 }
           - { jdk: 21, idea: 2024.3 }
           - { jdk: 21, idea: 2025.1 }
           - { jdk: 21, idea: 2025.2 }
+          - { jdk: 21, idea: 2025.3 }
           - { jdk: 21, idea: LATEST-EAP-SNAPSHOT }
     name: 'IDEA ${{ matrix.version.idea }}'
     env:

build.gradle

@@ -3,13 +3,13 @@ import com.hierynomus.gradle.license.tasks.LicenseFormat
 import org.jetbrains.intellij.platform.gradle.TestFrameworkType
 
 plugins {
-    id "org.jetbrains.intellij.platform" version "2.6.0"
-    id "com.github.hierynomus.license" version "0.16.1"
+    id("org.jetbrains.intellij.platform") version "2.10.5"
+    id("com.github.hierynomus.license") version "0.16.1"
 }
 
 
-group pluginGroup
-version pluginVersion
+group = pluginGroup
+version = pluginVersion
 
 apply plugin: 'idea'
 apply plugin: 'java'
@@ -19,8 +19,8 @@ apply plugin: 'checkstyle'
 apply plugin: 'jacoco'
 
 java {
-    sourceCompatibility = JavaVersion.VERSION_17
-    targetCompatibility = JavaVersion.VERSION_17
+    sourceCompatibility = JavaLanguageVersion.of(21)
+    targetCompatibility = JavaLanguageVersion.of(21)
 }
 
 repositories {
@@ -36,7 +36,7 @@ intellijPlatform {
     projectName = 'MapStruct-Intellij-Plugin'
     pluginConfiguration {
         ideaVersion {
-            sinceBuild = "241"
+            sinceBuild = "242"
             untilBuild = provider { null } as Provider<? extends String>
         }
     }
@@ -50,17 +50,17 @@ patchPluginXml {
     pluginDescription = htmlFixer('description.html')
 }
 
-task licenseTestData(type: LicenseCheck) {
+tasks.register('licenseTestData', LicenseCheck) {
     source = fileTree(dir: "testData").include("**/*")
 }
 
-task licenseFormatForKotlin(type: LicenseFormat) {
+tasks.register('licenseFormatForKotlin', LicenseFormat) {
     source = fileTree(dir: "src/main").include("**/*.kt").include("**/*.xml")
 }
 
 license {
-    header rootProject.file('etc/license.txt')
-    strictCheck true
+    header = file('etc/license.txt')
+    strictCheck = true
     mapping {
         java = 'SLASHSTAR_STYLE' // IntelliJ reports the JAVADOC_STYLE as a dangling comment
     }
@@ -75,28 +75,35 @@ licenseFormat.dependsOn licenseFormatForKotlin
 licenseTest.dependsOn licenseTestData
 
 checkstyle {
-    toolVersion '8.36.1'
-    config resources.text.fromUri("https://raw.githubusercontent.com/mapstruct/mapstruct/master/build-config/src/main/resources/build-config/checkstyle.xml")
+    toolVersion = '8.36.1'
+    config = resources.text.fromUri("https://raw.githubusercontent.com/mapstruct/mapstruct/master/build-config/src/main/resources/build-config/checkstyle.xml")
     configProperties = [
-            'checkstyle.cache.file': rootProject.layout.buildDirectory.get().asFile.toPath(  ).resolve( 'checkstyle-cachefile').toString(),
+            'checkstyle.cache.file': layout.buildDirectory.get().asFile.toPath(  ).resolve( 'checkstyle-cachefile').toString(),
             'basedir': 'https://raw.githubusercontent.com/mapstruct/mapstruct/master/build-config',
     ]
 }
 
 jacocoTestReport {
+    classDirectories.setFrom(instrumentCode)
     reports {
         xml.required = true
         html.required = true
     }
 }
 
 def versionToUse = System.getenv().getOrDefault( 'IDEA_VERSION', ideaVersion )
-def useInstaller = !versionToUse.containsIgnoreCase( "EAP" )
+def useIdeaInstaller = !versionToUse.containsIgnoreCase( "EAP" )
 dependencies {
     intellijPlatform {
-        ideaType == 'IC' ? intellijIdeaCommunity(versionToUse, useInstaller) : intellijIdeaUltimate(versionToUse, useInstaller)
-
-        jetbrainsRuntime()
+        // When versionToUse is 2025.3 or later then there is only a single distribution of IntelliJ
+        // This comparison can be removed if the oldest supported version of idea is 2025.3 (253) or later
+        if (('2025.3' <=> versionToUse) <= 0 ){
+            intellijIdea(versionToUse) {
+                useInstaller = useIdeaInstaller
+            }
+        } else {
+            ideaType == 'IC' ? intellijIdeaCommunity(versionToUse, useIdeaInstaller) : intellijIdeaUltimate(versionToUse, useIdeaInstaller)
+        }
 
         bundledPlugin( 'com.intellij.java' )
         bundledPlugin( 'org.jetbrains.kotlin' )
@@ -116,20 +123,20 @@ dependencies {
     testRuntimeOnly('org.immutables:value:2.10.1')
 }
 
-task libs(type: Sync) {
-    from configurations.runtimeClasspath
-    into layout.buildDirectory.dir("libs")
+tasks.register('libs', Sync) {
+    from(configurations.runtimeClasspath)
+    into(layout.buildDirectory.dir("libs"))
     preserve {
-        include 'mapstruct-intellij-*.jar'
-        include 'MapStruct-Intellij-*.jar'
+        include('mapstruct-intellij-*.jar')
+        include('MapStruct-Intellij-*.jar')
     }
-    rename 'mapstruct-1.5.3.Final.jar', 'mapstruct.jar'
+    rename('mapstruct-1.5.3.Final.jar', 'mapstruct.jar')
 }
 
-task testLibs(type: Sync) {
-  from configurations.testRuntimeClasspath
-  into "$buildDir/test-libs"
-  rename 'value-2.10.1.jar', 'immutables.jar'
+tasks.register('testLibs', Sync) {
+    from(configurations.testRuntimeClasspath)
+    into(layout.buildDirectory.dir("test-libs"))
+    rename('value-2.10.1.jar', 'immutables.jar')
 }
 
 test.dependsOn( libs, testLibs )

gradle.properties

@@ -2,10 +2,11 @@
 # https://www.jetbrains.com/intellij-repository/releases
 # https://www.jetbrains.com/intellij-repository/snapshots
 
-ideaVersion = 2024.1
+ideaVersion = 2024.2
 ideaType = IC
 sources = true
 runGenerators = true
+org.gradle.jvmargs=-Xmx1024m
 
 pluginGroup = org.mapstruct
 pluginName = mapstruct-intellij

gradle/wrapper/gradle-wrapper.jar

@@ -1,5 +1,7 @@
 distributionBase=GRADLE_USER_HOME
 distributionPath=wrapper/dists
-distributionUrl=https\://services.gradle.org/distributions/gradle-8.10.1-bin.zip
+distributionUrl=https\://services.gradle.org/distributions/gradle-8.14.3-bin.zip
+networkTimeout=10000
+validateDistributionUrl=true
 zipStoreBase=GRADLE_USER_HOME
 zipStorePath=wrapper/dists

gradle/wrapper/gradle-wrapper.properties

@@ -24,7 +24,7 @@
   <vendor url="https://www.mapstruct.org">MapStruct</vendor>
 
   <!-- please see https://www.jetbrains.org/intellij/sdk/docs/basics/getting_started/build_number_ranges.html for description -->
-  <idea-version since-build="241"/>
+  <idea-version since-build="242"/>
 
   <!-- please see https://www.jetbrains.org/intellij/sdk/docs/basics/getting_started/plugin_compatibility.html
        on how to target different products -->