Fix #10. Добавлен метод flatMap/Развернуть

Author: nixel2007

README.md

@@ -18,6 +18,7 @@
 * Пропустить
 * Различные
 * Обработать
+* Развернуть
 * Фильтровать
 * Сортировать
 * СортироватьПо
@@ -254,6 +255,46 @@
 Функция Обработать(Знач ФункцияОбработки, Знач ДополнительныеПараметры = Неопределено) Экспорт
 ```
 
+#### Развернуть
+
+```bsl
+// Развернуть каждый элемент коллекции в процессор коллекций.
+// Позволяет расширить имеющуюся коллекцию.
+// Например, разворачивание массива массивов сделает новый массив, содерщщий все элементы всех массивов.
+// Конвейерный метод.
+//
+// Параметры:
+//	ФункцияРазворачивания - Строка, ОписаниеОповещения - функция разворачивания.
+//		В случае передачи Строки формируется служебное описание оповещения, в контексте которого заданы переменные
+//		"Результат", "ДополнительныеПараметры", "Элемент".
+//		В случае передачи ОписанияОповещения обработчик данного описания должен содержать два параметра 
+//		(имена произвольные):
+//			Результат - ПроцессорКоллекций - Переменная, в которую должен быть
+//                                           помещен результат работы функции в виде ПроцессораКоллекций.
+//			ДополнительныеПараметры - Структура - Структура параметров, передаваемая функции разворачивания.
+//		
+//	ДополнительныеПараметры - Структура - Структура дополнительных параметров, передаваемая функции разворачивания.
+//		Служит для передачи дополнительных данных из прикладного кода в функцию разворачивания.
+//		По умолчанию содержит одно значение - Элемент.
+//
+// Возвращаемое значение:
+//	ПроцессорКоллекций - Инстанс класса "ПроцессорКоллекций".
+//
+// Примеры:
+//	1:
+//	ПроцессорКоллекций.Развернуть("Результат = ПроцессорыКоллекций.ИзСтроки(Элемент);");
+//
+//	2:
+//	Процедура МояФункцияРазворачивания(Результат, ДополнительныеПараметры) Экспорт
+//		Результат = ПроцессорыКоллекций.ИзСтроки(ДополнительныеПараметры.Элемент);
+//	КонецПроцедуры
+//	
+//	ФункцияРазворачивания = Новый ОписаниеОповещения("МояФункцияРазворачивания", ЭтотОбъект);
+//	ПроцессорКоллекций.Развернуть(ФункцияРазворачивания);
+//
+Функция Развернуть(Знач ФункцияРазворачивания, Знач ДополнительныеПараметры = Неопределено) Экспорт
+```
+
 #### Фильтровать
 
 ```bsl

src/internal/Классы/ПроцессорКоллекцийСлужебный.os

@@ -151,6 +151,36 @@
 
 КонецПроцедуры
 
+Процедура ВыполнитьРазвернуть(Результат, ДополнительныеПараметры) Экспорт
+	
+	Обработчик = ДополнительныеПараметры.Обработчик;
+	
+	Лог.Отладка("ВыполнитьРазвернуть %1", Обработчик.ИмяПроцедуры);
+	
+	Результат = Новый Массив;
+	
+	Если Обработчик.ДополнительныеПараметры = Неопределено Тогда
+		Обработчик.ДополнительныеПараметры = Новый Структура;
+	КонецЕсли;
+	Обработчик.ДополнительныеПараметры.Вставить("Элемент");
+	
+	Для Каждого Элемент Из Коллекция Цикл
+		Обработчик.ДополнительныеПараметры.Элемент = Элемент;
+		РезультатРазворачивания = Элемент;
+		ОписанияОповещений.ВыполнитьОбработкуОповещения(Обработчик, РезультатРазворачивания);
+		
+		ДСО = СтрШаблон("Результат разворачивания для элемента %1 должен иметь тип ПроцессорКоллекций", Элемент);
+		Ожидаем.Что(РезультатРазворачивания, ДСО).ИмеетТип("ПроцессорКоллекций");
+		
+		РезультатРазворачивания.ДляКаждого(
+			"ДополнительныеПараметры.Результат.Добавить(Элемент);",
+			Новый Структура("Результат", Результат)
+		);
+
+	КонецЦикла;
+	
+КонецПроцедуры
+
 Процедура ВыполнитьСортировать(Результат, ДополнительныеПараметры) Экспорт
 
 	Обработчик = ДополнительныеПараметры.Обработчик;

src/Классы/ПроцессорКоллекций.os

@@ -155,6 +155,52 @@
 
 КонецФункции
 
+// Развернуть каждый элемент коллекции в процессор коллекций.
+// Позволяет расширить имеющуюся коллекцию.
+// Например, разворачивание массива массивов сделает новый массив, содерщщий все элементы всех массивов.
+// Конвейерный метод.
+//
+// Параметры:
+//	ФункцияРазворачивания - Строка, ОписаниеОповещения - функция разворачивания.
+//		В случае передачи Строки формируется служебное описание оповещения, в контексте которого заданы переменные
+//		"Результат", "ДополнительныеПараметры", "Элемент".
+//		В случае передачи ОписанияОповещения обработчик данного описания должен содержать два параметра 
+//		(имена произвольные):
+//			Результат - ПроцессорКоллекций - Переменная, в которую должен быть
+//                                           помещен результат работы функции в виде ПроцессораКоллекций.
+//			ДополнительныеПараметры - Структура - Структура параметров, передаваемая функции разворачивания.
+//		
+//	ДополнительныеПараметры - Структура - Структура дополнительных параметров, передаваемая функции разворачивания.
+//		Служит для передачи дополнительных данных из прикладного кода в функцию разворачивания.
+//		По умолчанию содержит одно значение - Элемент.
+//
+// Возвращаемое значение:
+//	ПроцессорКоллекций - Инстанс класса "ПроцессорКоллекций".
+//
+// Примеры:
+//	1:
+//	ПроцессорКоллекций.Развернуть("Результат = ПроцессорыКоллекций.ИзСтроки(Элемент);");
+//
+//	2:
+//	Процедура МояФункцияРазворачивания(Результат, ДополнительныеПараметры) Экспорт
+//		Результат = ПроцессорыКоллекций.ИзСтроки(ДополнительныеПараметры.Элемент);
+//	КонецПроцедуры
+//	
+//	ФункцияРазворачивания = Новый ОписаниеОповещения("МояФункцияРазворачивания", ЭтотОбъект);
+//	ПроцессорКоллекций.Развернуть(ФункцияРазворачивания);
+//
+Функция Развернуть(Знач ФункцияРазворачивания, Знач ДополнительныеПараметры = Неопределено) Экспорт
+	
+	Если ТипЗнч(ФункцияРазворачивания) = Тип("Строка") Тогда
+		ФункцияРазворачивания = СформироватьВременноеОписаниеОповещения(ФункцияРазворачивания, ДополнительныеПараметры);
+	КонецЕсли;
+	ДополнитьСтруктуру(ФункцияРазворачивания.ДополнительныеПараметры, ДополнительныеПараметры, Истина);
+	
+	ПоложитьЯчейкуВКонвейер("Развернуть", ФункцияРазворачивания);
+	Возврат ЭтотОбъект;
+
+КонецФункции
+
 // Фильтровать коллекцию по условию.
 // Конвейерный метод.
 //

tests/КонвейерныеМетоды.os

@@ -34,6 +34,7 @@
 	ВсеТесты.Добавить("ТестДолжен_ПропуститьНесколькоЭлементов");
 	ВсеТесты.Добавить("ТестДолжен_ПолучитьРазличныеЭлементы");
 	ВсеТесты.Добавить("ТестДолжен_ПолучитьУвеличитьВсеЭлементыНаЕдиницуЧерезОбработку");
+	ВсеТесты.Добавить("ТестДолжен_СобратьДваПроцессораВОдин");
 	ВсеТесты.Добавить("ТестДолжен_ОтфильтроватьЭлементыМеньшеДвух");
 	ВсеТесты.Добавить("ТестДолжен_ОтсортироватьЭлементы");
 	ВсеТесты.Добавить("ТестДолжен_ОтсортироватьТаблицуПоКолонке");
@@ -86,6 +87,21 @@
 	КонецЦикла;
 КонецПроцедуры
 
+Процедура ТестДолжен_СобратьДваПроцессораВОдин() Экспорт
+	
+	ПроцессорКоллекций = ПолучитьПроцессорКоллекций();
+	Результат = ПроцессорКоллекций.Развернуть(
+			"Массив = Новый Массив;
+			|Массив.Добавить(Элемент);
+			|Массив.Добавить(Элемент + 1);
+			|Результат = ПроцессорыКоллекций.ИзКоллекции(Массив)"
+		).Фильтровать("Результат = Элемент = 2")
+		.Количество();
+	
+	Ожидаем.Что(Результат, "Процессоры коллекций должны сложиться и отфильтроваться").Равно(3);
+	
+КонецПроцедуры
+
 Процедура ТестДолжен_ОтфильтроватьЭлементыМеньшеДвух() Экспорт
 	ПроцессорКоллекций = ПолучитьПроцессорКоллекций();
 	Результат = ПроцессорКоллекций.Фильтровать("Результат = Элемент < 2").ВМассив();