feat(nix): add comprehensive Nix flake

.envrc

@@ -0,0 +1 @@
+use flake

.gitignore

@@ -659,3 +659,10 @@ obj/
 
 # End of https://www.toptal.com/developers/gitignore/api/qt,c++,clion,kotlin,python,android,pycharm,androidstudio,visualstudiocode,linux
 linux/.qmlls.ini
+
+# Nix
+result
+result-*
+
+# direnv
+.direnv

default.nix

@@ -0,0 +1,12 @@
+(import (
+  let
+    lock = builtins.fromJSON (builtins.readFile ./flake.lock);
+    nodeName = lock.nodes.root.inputs.flake-compat;
+  in
+  fetchTarball {
+    url =
+      lock.nodes.${nodeName}.locked.url
+        or "https://github.com/edolstra/flake-compat/archive/${lock.nodes.${nodeName}.locked.rev}.tar.gz";
+    sha256 = lock.nodes.${nodeName}.locked.narHash;
+  }
+) { src = ./.; }).defaultNix

flake.nix

@@ -0,0 +1,88 @@
+{
+  description = "AirPods liberated from Apple's ecosystem";
+
+  inputs = {
+    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
+    systems.url = "github:nix-systems/default";
+    flake-parts.url = "github:hercules-ci/flake-parts";
+    flake-compat.url = "https://flakehub.com/f/edolstra/flake-compat/1.tar.gz";
+    treefmt-nix.url = "github:numtide/treefmt-nix";
+  };
+
+  outputs =
+    inputs@{ flake-parts, systems, ... }:
+    flake-parts.lib.mkFlake { inherit inputs; } {
+      systems = import systems;
+      imports = [
+        inputs.treefmt-nix.flakeModule
+      ];
+
+      perSystem =
+        {
+          pkgs,
+          ...
+        }:
+        let
+          # Build time
+          nativeBuildInputs = with pkgs; [
+            cmake
+            pkg-config
+            qt6.wrapQtAppsHook
+            makeWrapper
+          ];
+
+          # Run time
+          buildInputs = with pkgs; [
+            qt6.qtbase
+            qt6.qtconnectivity
+            qt6.qtmultimedia
+            qt6.wrapQtAppsHook
+
+            openssl
+            bluez
+            libpulseaudio
+          ];
+
+          librepods = pkgs.stdenv.mkDerivation {
+            pname = "librepods";
+            version = "dev";
+
+            src = ./linux;
+
+            inherit nativeBuildInputs;
+            inherit buildInputs;
+
+            meta = {
+              description = "AirPods liberated from Apple's ecosystem";
+              homepage = "https://github.com/kavishdevar/librepods";
+              license = pkgs.lib.licenses.gpl3Only;
+              maintainers = [ "kavishdevar" ];
+              platforms = pkgs.lib.platforms.unix;
+              mainProgram = "librepods";
+            };
+          };
+        in
+        {
+          packages = {
+            default = librepods;
+            inherit librepods;
+          };
+
+          devShells.default = pkgs.mkShell {
+            name = "librepods-dev";
+
+            buildInputs =
+              with pkgs;
+              [
+                gdb
+              ]
+              ++ buildInputs;
+          };
+
+          treefmt = {
+            programs.nixfmt.enable = pkgs.lib.meta.availableOn pkgs.stdenv.buildPlatform pkgs.nixfmt-rfc-style.compiler;
+            programs.nixfmt.package = pkgs.nixfmt-rfc-style;
+          };
+        };
+    };
+}

shell.nix

@@ -0,0 +1,12 @@
+(import (
+  let
+    lock = builtins.fromJSON (builtins.readFile ./flake.lock);
+    nodeName = lock.nodes.root.inputs.flake-compat;
+  in
+  fetchTarball {
+    url =
+      lock.nodes.${nodeName}.locked.url
+        or "https://github.com/edolstra/flake-compat/archive/${lock.nodes.${nodeName}.locked.rev}.tar.gz";
+    sha256 = lock.nodes.${nodeName}.locked.narHash;
+  }
+) { src = ./.; }).shellNix